Perl 将输出打印到新文件时出现问题

Question

我想删除文本文件中以 HPL_ 开头的所有行新文件。请帮忙！

open(FILE,"<myfile.txt"); 
@LINES = <FILE>; 
close(FILE); 
open(FILE,">myfile.txt"); 
foreach $LINE (@LINES) { 
@array = split(/\:/,$LINE); 


my $file = "changed";

open OUTFILE, ">$file" or die "unable to open $file $!";

print OUTFILE $LINE unless ($array[0] eq "HPL_");

} 
close(FILE); 
close (OUTFILE);




exit;

Answer 1

您只想删除所有以HPL_ 开头的行吗？这很简单！

perl -pi -e 's/^HPL_.*//s' myfile.txt

是的，它确实只是一条线。 :-)

Answer 2

如果你不想使用单行，重写“写入文件”部分如下：

my $file = "changed";
open( my $outfh, '>', $file ) or die "Could not open file $file: $!\n";
foreach my $LINE (@LINES) { 
  my @array = split(/:/,$LINE);
  next if $array[0] eq 'HPL_';
  print $outfh $LINE;
}
close( $outfh );

请注意您每次通过循环时如何open()ing 文件。这导致文件只包含最后一行，因为使用 open() 和 > 意味着“覆盖文件中的内容”。这是您的代码存在的主要问题。

编辑：顺便说一句，你想清理你的代码。如我所示，使用词法文件句柄。始终在每个 Perl 程序的顶部添加 tchrist 发布的三行代码。使用open() 的三运算符版本。不要将整个文件放入一个数组中，就好像您尝试读取一个巨大的文件可能会导致您的计算机内存不足一样。你的程序可以重写为：

#!perl

use strict;
use autodie; 
use warnings FATAL => "all";

my $infile = "myfile.txt";
my $outfile = "changed.txt";

open( my $infh, '<', $infile );
open( my $outfh, '>', $outfile );
while( my $line = <$infh> ) {
    next if $line =~ /^HPL_/;
    print $outfh $line;
}
close( $outfh );
close( $infh );

注意使用use autodie，您无需将or die ... 添加到open() 函数，因为autodie pragma 会为您处理。

Answer 3

您的代码的问题是您在行处理循环中打开文件以进行输出，由于您使用“>”形式的打开，因此每次都打开文件以进行写入，从而消除任何先前的内容。

将 open() 的调用移动到文件顶部，循环上方，它应该可以工作。

另外，我不确定您的意图，但在示例的第 4 行，您重新打开输入文件以进行写入（使用“>”），这也会破坏其中包含的任何内容。

作为旁注，您可以尝试阅读 Perl 的 grep() 命令，该命令旨在完全满足您的需求，如下所示：

#!/usr/bin/perl
use strict;
use warnings;

open(my $in, '<', 'myfile.txt') or die "failed to open input for read: $!";
my @lines = <$in> or die 'no lines to read from input';
close($in);

# collect all lines that do not begin with HPL_ into @result
my @result = grep ! /^HPL_/, @lines; 

open(my $out, '>', 'changed.txt') or die "failed to open output for write: $!";
print { $out } @result;
close($out);