如何重构作为 Groovy 中方法调用参数的闭包中的重复？

Question

考虑这个现实世界的例子，它是通过 Rest Client Builder（Grails 插件）对同一个 REST 服务端点进行“GET”和“POST”调用而编写的代码。我不喜欢重复，因为标题和内容类型设置是相同的，但我不确定如何重构公共部分，因为它们正在调用传递给 get() 或 post() 方法调用的闭包上的方法.请在您的答案中提供一个很好地重构重复的具体示例。

   private def doGetCall(String endpoint, def config) {
       def response = new RestBuilder().get(config.baseURI+endpoint) {
           contentType("application/json")
           header("Authorization", "ApiKey " + config.base64EncodedApiKey)
           header("ClientId", config.clientId)
       }

       handleResponse(response, config, endpoint);
       return response;
   }

   private def doPostCall(String endpoint, def payload, def config) {
       def response = new RestBuilder().post(config.baseURI+endpoint) {
           contentType("application/json")
           header("Authorization", "ApiKey " + config.base64EncodedApiKey)
           header("ClientId", config.clientId)
           json(payload)
       }

       handleResponse(response, config, endpoint, payload)
       return response;
   }

Answer 1

这就够了吗？

class RestTestService {
    def rest

    def methodMissing(String name, args) {
        if( !( name in ['get', 'post'] ) ) { // can add PUT & DELETE in future
            // throw missing method exception for method names other than above
            throw new MissingMethodException(
               "Http Method $name does not exist or not yet implemented.") 
        }

        def (endpoint, config, payload) = args?.toList()

        def response = rest."$name"(config.baseURI + endpoint) {
            contentType( "application/json" )
            header("Authorization", "ApiKey " + config.base64EncodedApiKey )
            header( "ClientId", config.clientId )
            if ( name == 'post' && payload ) {
                json( payload )
            }
        }

        handleResponse(response, config, endpoint)

        return response
    }

    private void handleResponse(def response, def config, def endpoint) { ... }

    public def doGetCall(String endpoint, def config) {
        get( endpoint, config )
    }

    public def doPostCall(String endpoint, def payload, def config) {
        post( endpoint, config, payload )
    }
}

//resources.groovy
beans = {
    rest(grails.plugins.rest.client.RestBuilder)
}

上面使用methodMissing 来决定在运行时调用哪个http方法。
另请注意，我建议不要为每个http调用创建RestBuilder，而是将其用作上面resources.groovy中所示的bean，并在使用时将其注入到类中。如果它是一个 grails 工件（控制器、服务），那么它将自动连接，否则 bean rest 必须正确连接。 您可以使用doGetCall 和doPostCall 进行抽象，或者在需要时完全删除它们。

Answer 2

Groovy 1.8 添加了 Closure 组合，因此如果您使用的是使用 Groovy 1.8 或更高版本的 Grails 版本：

private def doGetCall(String endpoint, def config) {
    def response = new RestBuilder().get(config.baseURI+endpoint, composeRequest(config))

    handleResponse(response, config, endpoint);
    return response;
}

private def doPostCall(String endpoint, def payload, def config) {
    def response = new RestBuilder().post(config.baseURI+endpoint, composeRequest(config, { json(payload) }))

    handleResponse(response, config, endpoint, payload)
    return response;
}

private def composeRequest(def config, Closure clos = null) {
    def request = {
        contentType("application/json")
        header("Authorization", "ApiKey " + config.base64EncodedApiKey)
        header("ClientId", config.clientId)
    }
    if (clos != null) {
        request = request << clos
    }
    request
}