如何将 Groovy 闭包变量注入 Spock 模拟谓词参数？

Question

我在 Spock 交互文档中发现了一条有趣的语句：

http://spockframework.org/spock/docs/1.3/interaction_based_testing.html#_argument_constraints

最后一行约束，带有闭包谓词的例子：

1 * subscriber.receive({ it.size() > 3 && it.contains('a') })

我的问题是：Groovy 中有没有办法将此谓词作为变量传递？

我的测试环境代码：

class Something {
   Doer doer

   Something(Doer doer) {
      this.doer = doer
   }

   boolean doSth(x) {
      if (!doer.validate(x)) throw new RuntimeException()
      true
   }
}

class Doer {
   boolean validate(int x) {
      x == 2
   }
}

和测试代码：

   def "some test"() {
      given:
      def d = Mock(Doer)
      def s = new Something(d)

      when:
      s.doSth(2)

      then:
      1 * d.validate({ it == 2 }) >> true
   }

我想要达到的目标：

def "some test"() {
      given:
      def d = Mock(Doer)
      def s = new Something(d)
      def myClosureVar = { ??? }

      when:
      s.doSth(2)

      then:
      1 * d.validate(myClosureVar) >> true
   }

Answer 1

闭包接受一个参数，如it 所示，具有定义的值。该值是相应的方法参数。因此，无论您在交互之外定义什么闭包，您都需要确保交互将该参数传递给闭包，即您需要创建自己的（小而简单）闭包来评估外部（可能更长，更复杂）闭包带参数it:

1 * d.validate({ myClosureVar(it) }) >> true

抱歉重复，但我总是更喜欢在我的答案中使用完整的MCVE，以便您可以轻松复制、粘贴、编译和运行：

应用程序类：

package de.scrum_master.stackoverflow.q60341734

class Doer {
  boolean validate(int x) {
    x == 2
  }
}

package de.scrum_master.stackoverflow.q60341734

class Something {
  Doer doer

  Something(Doer doer) {
    this.doer = doer
  }

  boolean doSth(x) {
    if (!doer.validate(x)) throw new RuntimeException()
    true
  }
}

Spock 规范：

package de.scrum_master.stackoverflow.q60341734

import org.junit.Rule
import org.junit.rules.TestName
import spock.lang.Specification

class SomethingTest extends Specification {
  @Rule
  TestName testName

  def "some test"() {
    given:
    def d = Mock(Doer)
    def s = new Something(d)

    when:
    s.doSth(2)

    then:
    1 * d.validate({ println "$testName.methodName: closure parameter = $it"; it == 2 }) >> true
  }

  def "another test"() {
    given:
    def d = Mock(Doer)
    def s = new Something(d)
    def myClosureVar = { println "$testName.methodName: closure parameter = $it"; it == 2 }

    when:
    s.doSth(2)

    then:
    1 * d.validate({ myClosureVar(it) }) >> true
  }
}

控制台日志：

some test: closure parameter = 2
another test: closure parameter = 2