2021 年更新
这是一个在online playground 的Peggy.js 中运行的工作示例。 Peggy.js 是积极开发中的 PEG.js 的一个分支。 PEG.js 已被 David Maida 停用。
该示例显示了如何解析INDENT、SAMEDENT 和DEDENT 规则，以及如何使用解析位置。检查控制台日志。
它使用这些语法，其他解析器生成器可能不知道这些语法：
（文件顶部）
-
{{...}}（全局初始化程序）- 在解析器生成时运行 ...。
-
{...}（每解析初始化器）- 在解析器实例化时运行 ...。
（在文件中）
-
X = Y {...}（动作）——当Y成功时执行...。初始化程序中的变量可用。如果... 返回某些内容，它将替换Y 返回的内容。
-
$X – 返回使用 X 解析的文本，而不是其结果。
-
... @X ...（pluck 运算符）– 将 ... X ... 的结果替换为 X 的结果。
-
&{...}（谓词）–“并且... 也必须为真”。
-
X = &(...) – 如果 ... 成功，则 X 成功。 ... 不消耗任何输入。
请参阅docs 了解更多信息。
{{
console.clear()
console.log('Parser generated')
}}
{
let indentstack = []
let indent = ''
function found (what) {
let loc = location()
console.log(`[${loc.start.line}:${loc.start.column} - ${loc.end.line}:${loc.end.column}] found ${what}`)
}
console.log('Parser instantiated')
}
DOCUMENT = NEWLINES? @THINGS NEWLINES? _
THINGS = ( SAMEDENT @( OBJECT / LINE ) )*
OBJECT = key:KEY childs:(BLOCK / INLINE) {
found(`object "${key}"`)
let o = {}
o[key] = childs
return o
}
KEY = @$( [^ \t\r\n:]+ ) _ ':' _
BLOCK = NEWLINES INDENT @THINGS DEDENT
INLINE = line:LINE { return [line] }
LINE = text:$( (!EOL .)+ ) NEWLINES? {
found(`line "${text}"`)
return text
}
INDENT = &(
spaces:$( [ \t]+ ) &{
return spaces.length > indent.length
} {
indentstack.push(indent)
indent = spaces
}
) {
found('indent')
}
SAMEDENT = spaces:$( [ \t]* ) &{
return spaces === indent
} {
found('samedent')
}
/* Because of this rule, results cache must be disabled */
DEDENT = &{
indent = indentstack.pop()
return true
} {
found('dedent')
}
_ = [ \t]*
EOL = '\r\n' / '\n' / '\r'
NEWLINES = (_ EOL)+
/* Test with this input
H:
a
b
c
G:
d
e
f
*/
旧答案
这是对@Jakub Kulhan 语法的修复，适用于 PEG.js v 0.10.0。最后一行需要更改为 = &{ indent = indentStack.pop(); return true;}，因为 PEG.js 现在不再允许语法中的独立操作 ({...})。此行现在是一个谓词 (&{...})，它总是成功 (return true;)。
我还删除了pos = offset;，因为它给出了错误offset is not defined。可能 Jakub 指的是旧版本 PEG.js 中可用的一些全局变量。 PEG.js 现在提供了location() 函数，它返回一个包含偏移量和其他信息的对象。
// do not use result cache, nor line and column tracking
{ var indentStack = [], indent = ""; }
start
= INDENT? l:line
{ return l; }
line
= SAMEDENT line:(!EOL c:. { return c; })+ EOL?
children:( INDENT c:line* DEDENT { return c; })?
{ var o = {}; o[line] = children; return children ? o : line.join(""); }
EOL
= "\r\n" / "\n" / "\r"
SAMEDENT
= i:[ \t]* &{ return i.join("") === indent; }
INDENT
= &(i:[ \t]+ &{ return i.length > indent.length; }
{ indentStack.push(indent); indent = i.join(""); })
DEDENT
= &{ indent = indentStack.pop(); return true;}
从 v 0.11.0 开始，PEG.js 还支持Value Plucking operator、@，这将使编写此语法更加简单，但由于它目前不在在线解析器中，因此我将避免将其添加到此示例中.