带有修改的 XSLT 副本

Question

我一直在尝试在这些限制范围内工作，我使用的是 XSLT 1.0 {under .net}。 我希望能够做到以下几点： 我是 xsl:for-each'ing 通过一组类型的节点

   <node>
     <data> unknown unstructured xml </data>
     <owner></owner>
   </node>

我希望能够输出

   <node>
     <data> unknown unstructured xml </data>
     <!--RESULT of calling an XSL template with certain parameters -->
   </node>

到目前为止，我认为我可以在here 中执行类似的操作：

    <xsl:copy> 
        <xsl:apply-template name="findownerdetails">
           <xsl:with-param name="data" select="something" />
        </xsl:apply-template> 
    </xsl:copy> 

但这显然是无效的。有什么建议可以让这个工作或实现类似的东西吗？恐怕我不能只调用应用模板，因为我想要的模板将取决于我通过节点元素列表构建的一些数据。

任何建议表示赞赏

Answer 1

<xsl:template match="node">
  <node>
    <xsl:copy-of select="data"/>
    <!-- assuming this next bit in your question example
    is something you are happy with -->
    <xsl:call-template name="findownerdetails">
      <xsl:with-param name="data" select="something" />
    </xsl:call-template> 
  </node>
</xsl:template>

Answer 2

这是一个典型的问题示例，使用和覆盖 identity rule 可以得到最好的解决：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="owner">
    <owner-details>
      <xsl:value-of select="."/>
    </owner-details>
 </xsl:template>
</xsl:stylesheet>

在此 XML 文档上应用此转换时（基于提供的带有附加属性和所有者详细信息的 XML 文档）：

<node attr1="x" attr2="y">
    <data> unknown unstructured xml </data>
    <owner>
        <details>
            <name>John Smith </name>
            <profession>XSLT programmer</profession>
        </details>
    </owner>
</node>

产生想要的结果：

<node attr1="x" attr2="y">
   <data> unknown unstructured xml </data>
   <owner-details>John Smith XSLT programmer</owner-details>
</node>

请注意：

1. 身份模板以递归方式“按原样”复制文档中的每个节点。

2. 我们只覆盖我们希望以其他方式处理的元素的标识模板。任何匹配模式比标识模板更具体的模板都会覆盖它——XSLT 处理器总是为节点选择最具体的匹配模板。

3. 使用和覆盖标识规则是最基本的、最强大、最通用的和最优雅的 XSLT 设计模式。它专门用于几乎所有 XSLT 转换：用于删除/重命名/修改/添加特定节点并保持所有其他节点不变。

4. OP 在评论中建议此解决方案不允许传递参数。这不是真的。任何模板（包括身份规则）都可以编写为具有参数——当需要时。在这种特殊情况下，不需要通过模板传递参数。

5. 与owner匹配的模板不需要调用另一个模板 -- 这里可以完成所有所有者特定的处理。