将来自多个来源的事件和通知处理到 vb.net 中的主窗体的最佳方法

Question

我有一个 vb.net 应用程序，其中有一个主窗体。大约有 10 个类，每个类都有自己的功能，如 tcpactions、fileactions、串行端口操作等。用户与主窗体交互并执行某些操作，这些操作将调用这些类中的方法。现在我在主窗体中有一个通知文本区域，我想在这些类中显示当前正在执行的操作以及它们在通知区域中的结果。

例如，当用户单击表单中的“启动进程”按钮时，我会调用“ProcessActions”类中的“launchprocess”方法。现在此方法尝试启动大约 7 个不同的进程，并在启动后发送通知，例如“进程 1 启动”，如果失败，它会发送通知，例如“进程 1 启动失败”。

我目前使用事件处理程序并使用它们来显示通知，但是由于我必须处理的事件数量越来越多，因此我将来可能需要添加更多类。那么有没有更好的方法来处理来自其他类的通知。

Answer 1

我建议在主窗体可以响应的所有类中使用通用的自定义事件处理程序。首先定义一个新的 EventArgs 类来处理你发回的通知：

Public NotInheritable Class NtfyEventArgs
    Inherits EventArgs

    Private _Action As String

    Public ReadOnly Property Action As String
        Get
            Return _Action
        End Get
    End Property

    Public Sub New(ByVal action As String)
        _Action = action
    End Sub
End Class

接下来定义一个基类来引发通知：

Public Class Base
    Public Event Ntfy(ByVal sender As Object, ByVal e As NtfyEventArgs)

    Protected Sub RaiseNtfy(ByVal action As String)
        RaiseEvent Ntfy(Me, New NtfyEventArgs(action))
    End Sub
End Class

让您的其他每个类都继承自基类。然后发送通知就变得很容易了：

Public Class ProcessActions
    Inherits Base

    Public Sub LaunchProcess
        'Do stuff
        RaiseNtfy("Process 1 launched")

        'Do more stuff
        RaiseNtfy("Process 2 launched")
    End Sub
End Class

最后在你的主窗体中，监听子类引发的任何事件

Public Class Form1
    Private WithEvents process As New ProcessActions
    Private WithEvents file As New FileActions

    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        'Add Event handlers
        AddHandler process.Ntfy, AddressOf HandleNtfy
        AddHandler file.Ntfy, AddressOf HandleNtfy
    End Sub

    'One procedure to handle all the incoming notifications
    Private Sub HandleNtfy(ByVal sender as Object, ByVal e as NtfyEventArgs) 
        lblNtfy.Text = e.Action

        'If need to take different actions based on the class sending notification
        If TypeOf(Sender) Is ProcessActions Then
            'Specific code for ProcessActions
        End If
    End Sub
End Class