如何从 VBA 函数返回结果

Question

如何从函数返回结果？

例如：

Public Function test() As Integer
    return 1
End Function

这会导致编译错误。

如何让这个函数返回一个整数？

Answer 1

对于非对象返回类型，您必须将值分配给函数的名称，如下所示：

Public Function test() As Integer
    test = 1
End Function

示例用法：

Dim i As Integer
i = test()

如果函数返回一个对象类型，那么你必须像这样使用Set关键字：

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

示例用法：

Dim r As Range
Set r = testRange()

请注意，为函数名称分配返回值不会终止函数的执行。如果要退出函数，则需要明确说出Exit Function。例如：

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

文档：Function Statement

Answer 2

VBA 函数将函数名本身视为一种变量。因此，不要使用“return”语句，您只需说：

test = 1

但请注意，这并没有超出函数的范围。此语句之后的任何代码也将被执行。因此，您可以有许多赋值语句为test 分配不同的值，当您到达函数末尾时，无论该值是什么，都将是返回的值。

Answer 3

只是给函数名设置返回值还是不完全和Java（或其他）return语句一样，因为在java中，return退出函数，像这样：

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

在 VB 中，精确 等效项需要两行如果您没有在函数末尾设置返回值。因此，在 VB 中，确切的推论如下所示：

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

既然是这种情况，很高兴知道您可以像方法中的任何其他变量一样使用返回变量。像这样：

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

或者，返回变量工作原理的极端示例（但不一定是你应该如何实际编码的一个很好的例子）——那个会让你保持清醒在晚上：

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function

Answer 4

以下代码将返回值存储到变量retVal中，然后MsgBox可用于显示该值：

Dim retVal As Integer
retVal = test()
Msgbox retVal