XML 属性解析为 XMLList

Question

在下面的代码块中，如果我调试并查看它显示为 XMLList 的 var obj.theID。即使代码跟踪正确，我觉得它应该是一个字符串而不是 XMLList。

所以我的问题是如何让它分配一个字符串而不是一个 XMLList？

var myXML:XML = new XML(
<panels>
  <panel id="1"/>
  <panel id="2"/>
  <panel id="3"/>
</panels>
);

var panels:XMLList = new XMLList( myXML.children());

trace( panels.length()); // is as expected
for each( var panel:XML in (new XMLList( myXML.children())) ){
    var obj:Object = new Object( );

    // XMLList is assigned here but why? and how can I make it a string?
    obj.theID = panel.@id;

    // id is traced as expected but apparently it is just converting the XMLlist to a string.
    trace( panel.@id)
}

Answer 1

使用toString() 获取值。

例子：

var xml:XML = <thing>hello</thing>;

trace(xml.toString()) //hello

您的新代码：

var myXML:XML =
<panels>
    <panel id="1" />
    <panel id="2" />
    <panel id="3" />
</panels>;

var panels:XMLList = myXML.children();

var panel:XML;
for each(panel in panels)
{
    var obj:Object =
    {
        stringID: panel.@id.toString(),
        normalID: panel.@id
    };

    trace(typeof(obj.stringID), obj.stringID); //string
    trace(typeof(obj.normalID), obj.normalID); //xml
}

Answer 2

AS3 xml 解析器简单地读取任何原生 xml 内容，无论是作为字符串的属性还是节点数据，并且可以在没有类型转换的情况下直接使用。这是使 xml 在 Flash 中如此方便的原因之一。但是，如果您检查类型，它将以 XML 形式返回，除非您专门对其进行强制转换（这本质上就是 toString() 所做的）。

    for each( var panel:XML in panels ){
    var obj:Object = new Object( );

    obj.theID = panel.@id;

    // the native type is xml, tho can be read without conversion as a string 
    trace( typeof obj.theID) // type:xml
    trace( typeof panel.@id) // type:xml

    // simply cast it to string
    obj.theIDString = String(panel.@id); 
    trace( typeof obj.theIDString) // type:string
}

-- 更新--

注意 = XML 和 XMLlist 可以而且经常互换使用。他们每个人都可以访问一组相似的方法，但有一个重要的区别。 XML 可能只有一个根节点，而 XMLlist 可能有多个。这可能不会对正常使用产生太大影响，但取决于传入 xml 的结构，可能是一个关键的区别。通常，我只使用 XML 类型。这是xml vs xmllist上的一篇好文章。

干杯

Answer 3

这是 ActionScript 使用的 E4X 解析器的一部分。

XML 元素的子节点总是包装在 XMLList 中。即使 an 元素只有一个子元素或属性。

在对象上获取字符串的最简单方法是使用

var obj:Object = new Object(); obj.theID = panel.@id.toString();