SQL Server 打印文件

Question

Sql Server 中有类似 printf 的函数吗？我想要与 RAISERROR 函数相同的功能，但我不想抛出错误或打印消息，而是想将其写入 varchar，因为我的 ERP 不允许我处理错误消息.

这是 SQL Server 2000。

RAISERROR 的实际工作示例：

declare @name varchar(10)
set @name = 'George'

RAISERROR ('Hello %s.', 10, 1, 'George')

打印Hello George

我在寻找什么：

declare @name varchar(10), @message varchar(50)
set @name = 'George'

SET @message = printf('Hello %s.', 'George')
return @message

这将返回Hello George

Answer 1

PRINT 只是RAISERROR，严重性为 0。所以你可以使用。

declare @name varchar(10)
set @name = 'George'

RAISERROR ('Hello %s.', 0, 1, 'George') WITH NOWAIT

编辑以将其存储到一个变量中，您可以使用xp_sprintf 扩展存储过程。

declare @name varchar(10)
set @name = 'George'

DECLARE @ret varchar(500)
exec master..xp_sprintf @ret OUTPUT, 'Hello %s.', @name
PRINT @ret

Answer 2

如果您的格式字符串数量有限，并且能够将它们添加到系统消息中（通过sp_addmessage），您可以使用FORMATMESSAGE：

与 RAISERROR 语句一样，FORMATMESSAGE 通过用提供的参数值替换消息中的占位符变量来编辑消息。有关错误消息中允许的占位符和编辑过程的更多信息，请参阅 RAISERROR。

---

以下将是 SQL Server 2005 或更高版本的有效答案，但不幸的是，OP 正在为 SQL Server 2000 寻求解决方案：

---

这很丑陋，而且是对 Try/Catch 和 RAISERROR 的滥用：

declare @message varchar(50)

begin try
    RAISERROR('Hello %s',16,1,'george')
end try
begin catch
    set @message = ERROR_MESSAGE()
end catch

print @message

Answer 3

自 SQL Server 2016 起，formatmessage 和 raiserror 已得到扩展，使它们几乎可以像 C 的 printf 函数一样工作。第一个参数（以前必须是引用 sys.messages 中预定义消息的整数）现在可以是 printf 样式的格式字符串：

select formatmessage(
    'This is a string %s and this is an integer %i%sand this is a string weirdly padded with spaces <<%7.3s>>%sand this is a hex representation of an integer %x',
    'foo',
    42,
    char(13) + char(10),
    'bar',
    char(13) + char(10),
    1337
);

/* output:
This is a string foo and this is an integer 42
and this is a string weirdly padded with spaces <<    bar>>
and this is a hex representation of an integer 539
*/

虽然throwdoes not implicitly support this same formatting，但没有什么能阻止你using formatmessage together with this construct：

declare @errorMessage nvarchar(max) = formatmessage(
    'This is a string %s and this is an integer %i%sand this is a string weirdly padded with spaces <<%7.3s>>%sand this is a hex representation of an integer %x',
    'foo',
    42,
    char(13) + char(10),
    'bar',
    char(13) + char(10),
    1337
);

throw 50000, @errorMessage, 1;

/* output:
Msg 50000, Level 16, State 1, Line 21
This is a string foo and this is an integer 42
and this is a string weirdly padded with spaces <<    bar>>
and this is a hex representation of an integer 539
*/

Answer 4

这是一个使用 sql_variant 数据类型的简单 printf 过程。不幸的是，它仅适用于 SQL Server 2008 及更高版本。

CREATE PROCEDURE dbo.printf
  @string nvarchar(max),
  @p1 sql_variant = null,
  @p2 sql_variant = null,
  @p3 sql_variant = null
AS
BEGIN
  declare @str nvarchar(200), @pos int, @type char(1)
  select @str = @string, @pos = 0

  --- @p1
  set @pos = CHARINDEX('%', @str, @pos)
  if @pos > 0 and substring(@str, @pos, 2) = '%%'
    set @str = stuff(@str, @pos, 2, coalesce(cast(@p1 as nvarchar(100)),'<null>')) 

  --- @p2
  set @pos = CHARINDEX('%', @str, @pos)
  if @pos > 0 and substring(@str, @pos, 2) = '%%'
    set @str = stuff(@str, @pos, 2, coalesce(cast(@p2 as nvarchar(100)),'<null>')) 

  --- @p3
  set @pos = CHARINDEX('%', @str, @pos)
  if @pos > 0 and substring(@str, @pos, 2) = '%%'
    set @str = stuff(@str, @pos, 2, coalesce(cast(@p3 as nvarchar(100)),'<null>')) 

  print @str
END

这里是示例调用：

exec dbo.printf 'Hello %%', 'World'
exec dbo.printf 'Hello %%. Today is %% of the month', 'World', 28
declare @dd datetime; set @dd = getDate()
exec dbo.printf 'Hello %%. Today''s date is %%', 'World', @dd

Answer 5

如果您希望在变量中存储一些消息，那么 SET 应该足以让您处理吧？除非我不清楚这个问题。

SET @varcharVariable = 'message text';