有没有办法检查字符串是否以任意 4 个字母开头。我正在寻找这样的东西：
If string like "####*" then
'DO STUFF
end if
“#”用于数字，我需要同样的东西，但只用于字母。 这可以在没有 regEx 的情况下完成吗？
【问题讨论】：
我不知道不使用正则表达式的方法。我们可以尝试使用正则表达式Test 以及模式^[A-Z]{4}.*$：
Dim input As String
Dim regex As Object
Set regex = New RegExp
regex.Pattern = "^[A-Z]{4}.*$"
input = "ABCD blah"
If regex.Test(input) Then
'DO STUFF
End If
【讨论】：
Like 运算符在它的袖子上有一些技巧，以防止在这种情况下使用 RegEx。尽管如此，我也喜欢这个解决方案 ++
"^[A-Za-z]{4}"。你介意简单解释一下为什么.*$吗？我猜这是在寻找任何非换行符，直到字符串结束。但为什么？稍后将删除评论；）
^ 是一个锚点，确保定义的模式必须出现在字符串的开头。不会吗？
FilterXML() 函数的方法感兴趣（除了 JvdV 的有效解决方案），正如您提到的 “我不知道不使用常规的方法来做到这一点表达式" :-) @TimBiegeleisen
您可以使用Like 几乎与使用 RegEx 相同。
"{#}" - Like 运算符中不存在，但 "[A-Z]" 绝对有效
if string like "[A-Z][A-Z][A-Z][A-Z]*" then
'DO STUFF
end if
【讨论】：
If str Like "[a-zA-Z][a-zA-Z][a-zA-Z][a-zA-Z]*" 然后也要考虑小写:)。不错的解决方案，我也添加了另一个版本 =)。 ++
可以不使用正则表达式吗？
是的，没有特别需要Regular Expressions，因为Like 操作符非常有能力作为某种最后手段来处理这种情况，就像this 文章的作者所解释的那样。此外，RegEx 在较大的数据库上有点慢。尽管如此，RegEX 是一个很棒的工具！
@AlexandruHapco 提供的解决方案会告诉您字符串是否以 4 个大写字母开头。但要考虑下或上，你可以扩展这个逻辑：
If str Like "[a-zA-Z][a-zA-Z][a-zA-Z][a-zA-Z]*" Then
然而，为了缩短这一点，我们可以使用[!charlist] 告诉操作员我们正在寻找不在提供范围内的东西。换句话说，我们可以使用：
If str Like "[!0-9][!0-9][!0-9][!0-9]*" Then
当您的字符串包含除字母数字字符之外的任何其他字符时，最后一种解决方案将不起作用。
【讨论】：
Like这个解决方案+1。
* 在Like 中用于任意数量的字符。在RegEx 中，它用于检查它之前定义的模式的零个或多个匹配项。
FilterXML() 函数作为替代 :-)
使用FilterXML 函数的方法
WorksheetFunction FilterXML() 已添加到 ►Excel 2013 中，允许为给定的 XML 文档指定任何 XPath 搜索字符串，该文档不必是本地保存的文件（需要 @987654323 @函数），但可以是格式良好打开和关闭节点中的字符串，即我们的测试字符串，带有一些简单的节点添加（部分类似于html结构）。
调用示例
Sub TextXML()
Dim myString As String
myString = "ABCD blah"
If check(myString) Then
'DO STUFF
Debug.Print "okay"
Else
Debug.Print "oh no"
End If
End Sub
帮助功能
Function check(ByVal teststring As String) As Boolean
Const s As String = Chr(185) ' unusual character, e.g. Chr(185): "¹"
On Error GoTo oops
If Len(WorksheetFunction.FilterXML("<all><i>" & teststring & "</i></all>", "//i[substring(translate(.,'ABCDEFGHIJKLMNOPQRSTUVWXYZ','" & _
String(26, s) & "'),1,4)='" & String(4, s) & "']")) > 0 Then check = True
Exit Function
oops:
Err.Clear
End Function
tl;tr - 如何在 2013 年之前的 Excel 版本中使用 VBA
为了艺术，通过 XMLDOM 方法使用 XPath 的经典方式：
调用示例
Sub TextXML2()
Dim myString As String
myString = "ABCD blah"
If check2(myString) Then
'DO STUFF
Debug.Print "okay"
Else
Debug.Print "oh no"
End If
End Sub
帮助功能
Function check2(ByVal teststring As String) As Boolean
' Purpose: check if first 4 characters of a test string are upper case letters A-Z
' [0] late bind XML document
Dim xDoc As Object
Set xDoc = CreateObject("MSXML2.DOMDocument.6.0")
' [1] form XML string by adding opening and closing node names ("tags")
teststring = "<all><i>" & teststring & "</i></all>"
' [2] load XML
If xDoc.LoadXML(teststring) Then
' [3a] list matching item(s) via XPath
Dim myNodeList As Object
Set myNodeList = xDoc.SelectNodes(XPath())
'Debug.Print teststring, " found: " & myNodeList.Length
' [3b] return true if the item matches, i.e. the list length is greater than zero
If myNodeList.Length > 0 Then check2 = True
End If
End Function
Function XPath() As String
' Purpose: create XPath string to get nodes where the first 4 characters are upper case letters A-Z
' Result: //i[substring(translate(.,'ABCDEFGHIJKLMNOPQRSTUVWXYZ','¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹¹'),1,4)="¹¹¹¹"]
' get UPPER case alphabet
Const ABC As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
' define replacement string consisting of an unusual character repeated 26 times
Const UNUSUAL As String = "¹" ' << replace by your preferenced character
Dim replacement As String: replacement = String(Len(ABC), UNUSUAL)
'return XPath string
XPath = "//i[substring(translate(.,'" & ABC & "','" & replacement & "'),1,4)=""" & String(4, UNUSUAL) & """]"
End Function
【讨论】：
要测试几个字符（在这种情况下是前 4 个字母），您始终可以执行以下操作：
If Not (Mid(string, 1, 1) Like "#" And Mid(string, 2, 1) Like "#" _
And Mid(string, 3, 1) Like "#" And Mid(string, 4, 1) Like "#") Then
' DO STUFF
End If
当使用 Like 运算符时，键入的内容要多一些，但那又如何呢？此外，您可以在循环中使用Select Case...
另一种选择是使用IsNumeric(Mid(string, i, 1)) 而不是Mid(string, i, 1) Like "#" 等。
当然，这种方法对于 4 个字符仍然很实用，但不像 RegEx 那样灵活且不可扩展。
【讨论】：
Like 运算符。为什么不充分发挥它的潜力呢？你输入的比其他答案多=)。