折叠和减少的区别？

Question

尝试学习 F#，但在尝试区分 fold 和 reduce 时感到困惑。 Fold 似乎做了same thing 但需要一个额外的参数。这两个功能的存在是否有正当理由，或者它们的存在是为了容纳不同背景的人？ （例如：C#中的字符串和字符串）

这是从示例中复制的代码 sn-p：

let sumAList list =
    List.reduce (fun acc elem -> acc + elem) list

let sumAFoldingList list =
    List.fold (fun acc elem -> acc + elem) 0 list

printfn "Are these two the same? %A " 
             (sumAList [2; 4; 10] = sumAFoldingList [2; 4; 10])

Answer 1

Fold 为累加器采用显式初始值，而reduce 使用输入列表的第一个元素作为初始累加器值。

这意味着累加器和结果类型必须与列表元素类型匹配，而在fold 中它们可能不同，因为累加器是单独提供的。这反映在类型中：

List.fold : ('State -> 'T -> 'State) -> 'State -> 'T list -> 'State
List.reduce : ('T -> 'T -> 'T) -> 'T list -> 'T

此外，reduce 在空输入列表上引发异常。

Answer 2

除了 Lee 所说的，您可以根据 fold 定义 reduce，但不能（轻松）反过来：

let reduce f list = 
  match list with
  | head::tail -> List.fold f head tail
  | [] -> failwith "The list was empty!"

fold 为累加器采用显式初始值这一事实也意味着fold 函数的结果可以具有与列表中值的类型不同的类型。例如，您可以使用 string 类型的累加器将列表中的所有数字连接成文本表示：

[1 .. 10] |> List.fold (fun str n -> str + "," + (string n)) ""

使用reduce 时，累加器的类型与列表中值的类型相同 - 这意味着如果您有一个数字列表，则结果必须是一个数字。要实现前面的示例，您必须先将数字转换为string，然后再累加：

[1 .. 10] |> List.map string
          |> List.reduce (fun s1 s2 -> s1 + "," + s2)

Answer 3

让我们看看他们的签名：

> List.reduce;;
val it : (('a -> 'a -> 'a) -> 'a list -> 'a) = <fun:clo@1>
> List.fold;;
val it : (('a -> 'b -> 'a) -> 'a -> 'b list -> 'a) = <fun:clo@2-1>

有一些重要的区别：

• 虽然reduce 仅适用于一种类型的元素，但fold 中的累加器和列表元素可能属于不同类型。

• 使用reduce，您可以将函数f 应用于从第一个元素开始的每个列表元素：

  f (... (f i0 i1) i2 ...) iN。

  使用fold，您从累加器s开始应用f：

  f (... (f s i0) i1 ...) iN.

因此，reduce 会在空列表中生成 ArgumentException。此外，fold 比reduce 更通用；您可以使用fold 轻松实现reduce。

在某些情况下，使用reduce 更简洁：

// Return the last element in the list
let last xs = List.reduce (fun _ x -> x) xs

如果没有合理的累加器则更方便：

// Intersect a list of sets altogether
let intersectMany xss = List.reduce (fun acc xs -> Set.intersect acc xs) xss

一般来说，fold 使用任意类型的累加器会更强大：

// Reverse a list using an empty list as the accumulator
let rev xs = List.fold (fun acc x -> x::acc) [] xs

Answer 4

fold 是一个比reduce 更有价值的函数。您可以根据fold 定义许多不同的函数。

reduce 只是fold 的一个子集。

折叠的定义：

let rec fold f v xs =
    match xs with 
    | [] -> v
    | (x::xs) -> f (x) (fold f v xs )

按折叠定义的函数示例：

let sum xs = fold (fun x y -> x + y) 0 xs

let product xs = fold (fun x y -> x * y) 1 xs

let length xs = fold (fun _ y -> 1 + y) 0 xs

let all p xs = fold (fun x y -> (p x) && y) true xs

let reverse xs = fold (fun x y -> y @ [x]) [] xs

let map f xs = fold (fun x y -> f x :: y) [] xs

let append xs ys = fold (fun x y -> x :: y) [] [xs;ys]

let any p xs = fold (fun x y -> (p x) || y) false xs 

let filter p xs = 
    let func x y =
        match (p x) with
        | true -> x::y
        | _ -> y
    fold func [] xs