在 VB.NET 中使用鼠标滚轮和 Ctrl 控制 WinForms 的缩放级别

Question

如果我有一个 winform，我可以知道如何使用 Ctrl + 鼠标滚轮来控制应用程序中字体的缩放级别（当然还有应用程序窗口本身）？我看到 Scroll Wheel 事件中有一个 Delta，但不确定它是如何工作的。有没有我可以查看的代码示例？

Answer 1

对于 CrystalReportViewer1

只要放 CrystalReportViewer1.Zoom(ZoomValue) 而不是 Sub Zoom 中的 Me.Text = ZoomValue.ToString() 行

Answer 2

我怀疑你可以测试一下：

（VB.NET）：

If (ModifierKeys And Keys.Control) = Keys.Control Then

(C#):

if( (ModifierKeys  & Keys.Control) == Keys.Control )

检查控制键是否按下。

Answer 3

您必须处理KeyDown 和KeyUp 事件才能确定Ctrl 键是否被按住。该值应存储在类级别，因为除了KeyDown 和KeyUp 事件之外的其他子例程将使用它。

然后您编写代码来处理表单的MouseWheel 事件。向下滚动（朝向您）会导致MouseEventArgs 的Delta 属性为负值。向上滚动显然是相反的。 Delta 属性的值当前始终为 120。

微软设置这个值的原因如下：

目前，120 是一个定位器的标准值。如果引入更高分辨率的鼠标，WHEEL_DELTA 的定义可能会变小。大多数应用程序应检查正值或负值，而不是总和。

在您的上下文中，您只需检查 Delta 的符号并执行操作。

这是一个实现基本“缩放”功能的示例代码：

Public Class Form1
    Enum ZoomDirection
        None
        Up
        Down
    End Enum

    Dim CtrlIsDown As Boolean
    Dim ZoomValue As Integer

    Sub New()

        ' This call is required by the designer.
        InitializeComponent()

        ' Add any initialization after the InitializeComponent() call.
        ZoomValue = 100
    End Sub

    Private Sub Form1_KeyDown_KeyUp(ByVal sender As Object, _
                                    ByVal e As KeyEventArgs) _
                Handles Me.KeyDown, Me.KeyUp

        CtrlIsDown = e.Control
    End Sub

    Private Sub Form1_MouseWheel(ByVal sender As Object, 
                                 ByVal e As MouseEventArgs) _
                Handles Me.MouseWheel

        'check if control is being held down
        If CtrlIsDown Then
            'evaluate the delta's sign and call the appropriate zoom command
            Select Case Math.Sign(e.Delta)
                Case Is < 0
                    Zoom(ZoomDirection.Down)
                Case Is > 0
                    Zoom(ZoomDirection.Up)
                Case Else
                    Zoom(ZoomDirection.None)
            End Select
        End If
    End Sub

    Private Sub Zoom(ByVal direction As ZoomDirection)
        'change the zoom value based on the direction passed

        Select Case direction
            Case ZoomDirection.Up
                ZoomValue += 1
            Case ZoomDirection.Down
                ZoomValue -= 1
            Case Else
                'do nothing
        End Select

        Me.Text = ZoomValue.ToString()
    End Sub
End Class

阅读以下内容以获取有关您的问题的更多信息：

1. MSDN: Control.KeyDown Event
2. MSDN: Control.KeyUp Event
3. MSDN: Control.MouseWheel Event
4. MSDN: MouseEventArgs Class