Haskell：在没有stackoverflow的情况下大量重复一个函数

Question

作为 Haskell 的新手，我正在尝试多次迭代一个函数（例如逻辑图）。在命令式语言中，这将是一个简单的循环，但是在 Haskell 中，我最终会出现堆栈溢出。以这段代码为例：

main  = print $ iter 1000000

f x = 4.0*x*(1.0-x)

iter :: Int -> Double
iter 0 = 0.3
iter n = f $ iter (n-1)

对于少量的迭代，代码可以工作，但对于一百万次迭代，我得到堆栈空间溢出：

Stack space overflow: current size 8388608 bytes.
Use `+RTS -Ksize -RTS' to increase it.

我不明白为什么会发生这种情况。尾递归在这里应该没问题。 也许问题是懒惰的评估。我尝试了几种强制严格评估的方法，在不同的位置插入$! 或seq，但没有成功。

Haskell 对函数进行大量迭代的方法是什么？

我尝试过相关帖子的建议：here 或here，但我总是以stackoverflow 结束大量迭代，例如main = print $ iterate f 0.3 !! 1000000。

Answer 1

问题在于你的定义

iter :: Int -> Double
iter 0 = 0.3
iter n = f $ iter (n-1)

试图以错误的方向进行评估。展开几步，我们得到

iter n = f (iter (n-1))
       = f (f (iter (n-2)))
       = f (f (f (iter (n-3))))
       ...

必须先构建从iter 1000000 到iter 0 的整个调用堆栈，然后才能评估任何内容。用严格的语言也是一样的。您必须对其进行组织，以便可以在重复之前进行部分评估。通常的方法是有一个累积参数，比如

iter n = go n 0.3
  where
    go 0 x = x
    go k x = go (k-1) (f x)

然后添加严格性注解——以防编译器尚未添加它们——将使其顺利运行而不会消耗堆栈。

iterate 变体与您的iter 存在相同的问题，只是调用堆栈是由内向外构建的，而不是由外向内构建的。但是由于iterate 是由内而外构建它的调用堆栈，所以更严格的iterate 版本（或者之前强制进行早期迭代的消费模式）解决了这个问题，

iterate' :: (a -> a) -> a -> [a]
iterate' f x = x `seq` (x : iterate' f (f x))

计算iterate' f 0.3 !! 1000000没有问题。