AS3：mouseX 在鼠标移动之前不会更新

Question

我正在用简单的鼠标控制制作游戏。基本上，如果玩家将光标移动到角色的右侧，他就会向右移动，反之亦然。但是如果你停止移动鼠标，Flash 会忽略一个停止角色的条件，直到你再次移动鼠标，所以这个人只会继续向同一个方向移动，直到你移动光标。如果每帧都更新 mouseX 和播放器的位置，为什么会发生这种情况？以下是输入条件：

stage.addEventListener(MouseEvent.MOUSE_MOVE, CTRLupdateMousePosition)

    private function CTRLupdateMousePosition(e:Event):void 
    {
        if (mouseX > shaman_legs.x-2 - shaman_legs.width / 2 && mouseX < shaman_legs.x+2 + shaman_legs.width / 2) {
            CTRLleftButtonDown = false
            CTRLrightButtonDown = false
        } else if (mouseX < shaman_legs.x - shaman_legs.width / 2 && GlobalVariableLibrary.COREgamePaused == false) {
            CTRLleftButtonDown = true
            CTRLrightButtonDown = false
        } else if (mouseX > shaman_legs.x + shaman_legs.width / 2 && GlobalVariableLibrary.COREgamePaused == false) {
            CTRLleftButtonDown = false
            CTRLrightButtonDown = true
        }
    }

下面是通过移动角色和播放动画来响应玩家输入的代码：

addEventListener(Event.ENTER_FRAME, playerControl)

    private function playerControl(e:Event):void {
        trace("LeftDown:"+CTRLleftButtonDown, "RightDown:"+CTRLrightButtonDown)
        boxSensor.x = shaman_legs.x
        soulCatcher.x = shaman_legs.x
        if (CTRLleftButtonDown == false && CTRLrightButtonDown == false && GlobalVariableLibrary.COREgamePaused == false) {
            shaman_legs.gotoAndPlay("idle")
            shaman_armsDown.gotoAndPlay("idle")
        } else if (CTRLleftButtonDown && shaman_legs.x > 40 && GlobalVariableLibrary.COREgamePaused == false) {
            shaman_legs.gotoAndPlay("walkLeft")
            shaman_armsDown.gotoAndPlay("walk")
            shaman_legs.x -= GlobalVariableLibrary.CHARspeed
            shaman_mask.x -= GlobalVariableLibrary.CHARspeed
            shaman_armsDown.x -= GlobalVariableLibrary.CHARspeed
            shaman_armsUp.x -= GlobalVariableLibrary.CHARspeed
        } else if (CTRLrightButtonDown && shaman_legs.x < 760 && GlobalVariableLibrary.COREgamePaused == false) {
            shaman_legs.gotoAndPlay("walkRight")
            shaman_armsDown.gotoAndPlay("walk")
            shaman_legs.x += GlobalVariableLibrary.CHARspeed
            shaman_mask.x += GlobalVariableLibrary.CHARspeed
            shaman_armsDown.x += GlobalVariableLibrary.CHARspeed
            shaman_armsUp.x += GlobalVariableLibrary.CHARspeed
        }
    }

Answer 1

您自己陈述了解决方案：如果鼠标没有移动，MouseEvent 将不会被调度。但只有MouseEvent 的处理程序会更改变量。变量永远不会改变，角色也不会停止。

MouseEvent 在这里根本不合适。

使用对象的鼠标坐标也容易得多，因为无论如何您都希望它们相对于它的位置。

这是一个非常简单的示例程序，说明如何使用对象的mouseX 和mouseY 属性，而不是使用主时间线的属性并添加对象的坐标。它不使用MouseEvent，因为您亲身体验过：它没有做您想做的事。

import flash.display.Sprite;
import flash.events.Event; 

const SPEED:Number = 1;

var box:Sprite = new Sprite();
box.graphics.beginFill(0xff0000);
box.graphics.drawRect(-50, -20, 100, 40);
box.graphics.endFill();

addChild(box);

box.x = box.y = 200;

addEventListener(Event.ENTER_FRAME, onLoop);

function onLoop(e:Event):void
{
    var halfHeight:Number = box.height / 2, halfWidth:Number = box.width / 2;         
    if (box.mouseX > halfWidth)
        box.x += SPEED;
    else if (box.mouseX < -halfWidth)
        box.x -= SPEED;

    if (box.mouseY > halfHeight)
        box.y += SPEED;
    else if (box.mouseY < -halfHeight)
        box.y -= SPEED;
}

在一个新的空项目的时间线上尝试一下。

---

这是题外话，但请将萨满的这些部分放入一个容器中，而不是将它们单独移动相同的数量。