AS3 - 使用 For 循环更新数组中的多个点及其值

Question

我对 AS3 有点陌生（但不是真正的编码）所以请原谅我的无知。我正在创建一个小函数，它将由 Main 函数调用以更新 52 个指针的位置，这些指针具有多个点对象（空影片剪辑）的 x 和 y 位置。然后它还将使用这些值更新两个全局数组（一个数组用于 x，一个用于 y）。

问题是，由于它们有 52 个，而且它们的数量可能会增加，我希望能够使用 FOR 函数来做到这一点，但我似乎无法弄清楚出去。

我收到此错误：未定义属性_point的访问。

这是一段梦寐以求的代码：

function happyFunc():void
{
    var avpointers:int = 52;
    var vpointx:Array = new Array();
    var vpointy:Array = new Array();        
    for (aa=0; aa<vpointers; aa++)
    {
        vpointx[aa] = _point[aa].x;
        vpointy[aa] = _point[aa].y;
    }
}

这是我一直坚持的代码......

function reallySadFunc():void
{
_point1 = localToGlobal(new Point(point1.x,point1.y));
//...
_point52 = localToGlobal(new Point(point52.x,point1.y));
vpointx[0] = _point1.x;
vpointx[1] = _point2.x;
//...
//oh god there are 104 lines of this why do I have to suffer
}

谢谢！

Answer 1

如果我正确阅读了您的问题，我认为这就是您所需要的：

public static const CLIP_COUNT:int = 52;

// ...

private function happyFunc(parentClip:DisplayObjectContainer):void
{
    var vpointx:Vector.<Number> = new Vector.<Number>(CLIP_COUNT, true);
    var vpointy:Vector.<Number> = new Vector.<Number>(CLIP_COUNT, true);

    var clipPoint:Point = new Point ();
    var globalPoint:Point;

    for (var i:int = 0; i < CLIP_COUNT; i++)
    {
        var childClip:DisplayObject = parentClip.getChildByName("point" + 
            (i + 1).toString());

        clipPoint.x = childClip.x;
        clipPoint.y = childClip.y;

        globalPoint = parentClip.localToGlobal(clipPoint);

        vpointx[i] = globalPoint.x;
        vpointy[i] = globalPoint.y;
    }

    // do something with vpointx and vpointy - they're local variables
    // and will go out of scope unless you declare them as class members
    // or somehow return them from this function.
}

此函数通过获取父显示对象（包含 52 个影片剪辑的那个 - 这可能是 Stage）并通过按名称获取每个影片剪辑来遍历它们。该代码假定您的影片剪辑名为point1、point2、...、point52。

为了加快本地到全局坐标的转换，创建了两个Point 对象，然后在for 循环期间重复使用，以避免创建许多临时Point 实例。

不要使用Array，而是使用Vector.<Number> - 这个类比Array 有更好的性能。