AS3 如何成为矢量列表的头部？

Question

我有一个用于 ip 和端口列表以及套接字连接的向量，当连接丢失时，我单击按钮并从向量列表中调用下一个 ip 和端口。

我的问题是当我完成我的列表时，我如何成为列表的头部？

这是我当前的代码

public class UriIterator 
{
     private var _availableAddresses: Vector.<SocketConnection> = new Vector.<SocketConnection>();


    public function UriIterator() 
    {

    }


    public function withAddress(host: String, port: int): UriIterator {
        const a: SocketConnection = new SocketConnection(host, port);
        _availableAddresses.push(a);
        return this;
    }

     public function get next(): SocketConnection{
        return _availableAddresses.length ? _availableAddresses.pop() : null;
    }
}

谢谢

Answer 1

需要对您的代码稍作调整：

public function get next():SocketConnection
{
    // Get the next one.
    var result:SocketConnection = _availableAddresses.pop();

    // Put it back at the other end of the list.
    _availableAddresses.unshift(result);

    return result;
}

Answer 2

在当前实现中，您只能遍历列表一次。您需要更改代码以保持列表不变：

public class UriIterator 
{
    private var _currentIndex:int = 0;
    private var _availableAddresses: Vector.<SocketConnection> = new Vector.<SocketConnection>();


    public function withAddress(host: String, port: int): UriIterator {
        const a: SocketConnection = new SocketConnection(host, port);
        _availableAddresses.push(a);
        return this;
    }

    public function get first():SocketConnection {
        _currentIndex = 0;
        if (_currentIndex >= _availableAddresses.length) 
            return null;
        return _availableAddresses[_currentIndex++];
   }

   public function get next(): SocketConnection {
        if (_currentIndex >= _availableAddresses.length) 
            return null;
        return _availableAddresses[_currentIndex++];
   }
}

现在要获得第一个条目，请致电 const firstConn:SocketConnection = iterator.first，而要获得其余条目，请继续致电 iterator.next。