使用 Perl 或 PHP 的 HTTP 多部分响应答案

【问题标题】：HTTP multipart response using Perl or PHP使用 Perl 或 PHP 的 HTTP 多部分响应
【发布时间】：2012-01-04 23:47:44
【问题描述】：

是否可以像多部分请求一样提供 HTTP 多部分响应（使用 Perl/PHP）？这个场景就像，我想提供一个 URL，它带有一个 EmployeeID 的参数，作为回报，响应应该包括员工的照片、最新的工资单以及姓名、年龄和地址等信息。接收端不是浏览器，而是一个程序，它会得到这个响应并稍后处理它们。关于如何做到这一点的任何想法？

要提供有关上述问题的更多信息，我必须向我的朋友提供一个 URL，他将以编程方式接收响应。例如（在 Perl 中）：

$response = $ua->request($my_url)

我的应用程序应该不仅响应数据，还响应文件！我被要求让它返回多部分响应。

我现在不知道如何从编码本身开始。谷歌搜索“多部分响应”没有返回我可以学习和开始的页面。但是，chansen 的评论以及他的代码示例 https://gist.github.com/1391017 确实很有帮助。非常感谢。

【问题讨论】：

@srikanth-vittal 这个gist.github.com/1391017 应该让你开始。
@chansen 感谢您的链接。这正是我一直在寻找的。我还用更多细节更新了我的问题。
版主重新打开了这个问题并删除了几个 cmets 到这个 cmets 使现有 cmets 脱离上下文，我希望有一个选项可以显示完整的历史记录，包括版主无能。

标签： php perl http response multipart

【解决方案1】：

我正在冒充我原来的https://gist.github.com/1391017 作为回复。

#!/usr/bin/perl
use strict;
use warnings;

use HTTP::Response;

my $response = HTTP::Response->new(
    200, 'OK', [ 'Content-Type' => 'multipart/form-data' ]
);

$response->protocol('HTTP/1.1');
$response->date(time);
$response->server('Foo/1.0');

my $name = HTTP::Message->new([
    'Content-Type'        => 'text/plain; charset=UTF-8',
    'Content-Disposition' => 'form-data; name="name"',
], 'John Doe');

$response->add_part($name);

my $note = HTTP::Message->new([
    'Content-Type'        => 'text/plain; charset=UTF-8',
    'Content-Disposition' => 'form-data; name="note"',
], <<'NOTE');
Resources:
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Message.pm
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Response.pm
  o http://tools.ietf.org/html/rfc2388
  o http://tools.ietf.org/html/rfc2616
NOTE

$response->add_part($note);

my $blob = HTTP::Message->new([
    'Content-Type'        => 'application/octet-stream',
    'Content-Disposition' => 'form-data; name="blob"; filename="blob.bin"',
]);
$blob->add_content('a chunk');
$blob->add_content(' of data');

$response->add_part($blob);

print $response->as_string;

输出：

HTTP/1.1 200 OK
Date: Thu, 24 Nov 2011 10:03:25 GMT
Server: Foo/1.0
Content-Type: multipart/form-data; boundary=xYzZY

--xYzZY
Content-Type: text/plain; charset=UTF-8
Content-Disposition: form-data; name="name"

John Doe
--xYzZY
Content-Type: text/plain; charset=UTF-8
Content-Disposition: form-data; name="note"

Resources:
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Message.pm
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Response.pm
  o http://tools.ietf.org/html/rfc2388
  o http://tools.ietf.org/html/rfc2616

--xYzZY
Content-Type: application/octet-stream
Content-Disposition: form-data; name="blob"; filename="blob.bin"

a chunk of data
--xYzZY--

【讨论】：