尝试使用 Cont monad 进行锻炼。语法问题

Question

经过一些研究（[1]、[2]、[3] 等），我正在尝试通过自己尝试一些示例来完成延续单子的工作。

[1] 的第二个答案建议使用延续来表达阶乘。我的解决方案如下：

Cont ($ (fact 0)) = return 1
Cont ($ (fact n)) = Cont ($ (fact (n-1))) >>= (\x -> Cont ($ (n*x)))

我在纸上做了一些模拟，解决方案应该是正确的。

但是我无法让它被 GHC 消化。当然我重命名了fact函数，但还是不开心。

我最近的尝试是https://gist.github.com/Muzietto/595bef1815ddf375129d 并一如既往地提供parse error in pattern \c -> .....

谁能建议这些定义的运行实现？

[1]How and why does the Haskell Cont monad work?

[2]http://hackage.haskell.org/package/mtl-1.1.0.2/docs/Control-Monad-Cont.html

[3]https://wiki.haskell.org/MonadCont_under_the_hood

Answer 1

首先，您不能以发布的方式定义函数，原因与您无法实现前驱函数的原因相同，如下所示：

1 + (predecessor x) = x

函数只能通过以下形式的方程来定义

f pattern1 .. patternK = expression

请注意，f 必须在顶层找到。

对于使用 continuation monad 的阶乘函数，您可以按如下方式简化您的尝试：

fact :: Int -> Cont r Int
-- Your own code:
-- Cont ($ (fact 0)) = return 1
fact 0 = return 1
-- Cont ($ (fact n)) = Cont ($ (fact (n-1))) >>= (\x -> Cont ($ (n*x)))
fact n = fact (n-1) >>= \x -> return (n*x)

-- the "real" factorial function, without monads
factorial :: Int -> Int
factorial n = runCont (fact n) id

注意，上面的return (n*x)确实是Cont ($ (n*x))，但我认为前者的可读性更好，也是因为它没有破坏抽象。事实上，一旦按上述方式编写，它就可以在 任何 monad 中工作。

或者，使用do 表示法。

fact :: Int -> Cont r Int
fact 0 = return 1
fact n = do
   x <- fact (n-1)
   return (n*x)

或者使用仿函数操作符：

fact :: Int -> Cont r Int
fact 0 = return 1
fact n = (n*) <$> fact (n-1)