Vala 产量未返回

Question

我在 Vala 中编写异步函数时遇到问题。
我知道函数的回调必须在某处注册才能在 yield 语句之后继续执行，所以我将它添加到 GLib 主循环中，以便使用Idle.add 定期调用。这是我的虚拟代码：

async void loop_func()
{
    var id = Idle.add(loop_func.callback);
    message("Added idle %u",id);

    yield;
    message("yielded successfully 1");

    yield;
    message("yielded successfully 2");

    for (var i = 0; i < 20; i++)
    {
        message("%d",i);
        yield;
    }

    message("finished");
}

int main()
{
    var loop = new GLib.MainLoop();
    loop_func.begin(() => {loop.quit();});
    loop.run();
    return 0;
}

尽管如此，第二条 yield 语句之后的代码永远不会被执行。 这可以从输出中看出：

$ ./async   
** Message: 20:07:24.932: async.vala:4: Added idle 1
** Message: 20:07:24.932: async.vala:7: yielded successfully 1

然后它挂起。
我在这里错过了什么？

Answer 1

虽然 GLib 反复调用空闲函数直到它告诉它停止（通过返回 false），但异步函数的 .callback 似乎在被调用后立即退出重复。

这可以通过每次在 yield 语句之前再次添加回调来克服：

async void loop_func()
{
    for (var i = 0; i < 20; i++)
    {
        Idle.add(loop_func.callback);
        yield;
    }
}

另一种（可能更有效）的方法是忽略异步函数的回调返回的值：

async void loop_func()
{
    var id = Idle.add(() => {loop_func.callback(); return Source.CONTINUE;});

    for (var i = 0; i < 20; i++)
    {
        yield;
    }

    Source.remove(id);
}