使用 common lisp 展平列表

Question

我正在阅读 Paul Graham 的《On Lisp》一书。在第 4 章“实用函数”中，他给出了对列表进行操作的小函数的示例，这对编写更大的程序很有帮助。

其中一个是flatten。给定任意级别的嵌套列表作为参数，flatten 将删除所有嵌套元素并将它们放在顶层。

以下是我实现扁平化的尝试：

(defun flatten (lst)
  (labels ((rflatten (lst1 acc)
                     (dolist (el lst1)
                       (if (listp el)
                         (rflatten el acc)
                         (push el acc)))
                     acc))
    (reverse (rflatten lst nil))))

但是上面的函数并不能正确地展平列表。

; returns (1) instead of (1 2)
(print (flatten '(1 (2))))
(1)

使用(1 (2)) 调用函数返回(1) 而不是(1 2)。

我找不到我的扁平化实现有什么问题。是我使用的方式吗 labels?还是我使用dolist 宏的方式？ dolist 宏总是返回 nil。但这并不重要，因为我使用累加器 acc 来存储扁平列表。

Answer 1

由conses 构建结果的非递归代码，在comments 之后并从code 开始，user:Sylwester：

(defun flatten (lst &optional back acc)
  (loop
     (cond 
        ((consp lst) (psetq lst (cdr lst)              ; parallel assignment
                           back (cons (car lst) back)))
        (back
                  (if (consp (car back))  
                    (psetq lst (cdar back)
                          back (cons (caar back) (cdr back)))
                    (psetq acc (if (car back) (cons (car back) acc) acc)
                          back (cdr back))))
        (t     
               (return acc)))))                        ; the result

它不漂亮，但它seems to work。并行赋值PSETQ用于模拟尾递归调用帧更新，无需担心精确排序。

实现与良好编码的过程相同的过程

(defun flatten2 (l z)
    (cond
        ((endp l) z)
        ((listp (car l)) (flatten2 (car l) (flatten2 (cdr l) z)))
        ((atom (car l)) (cons (car l) (flatten2 (cdr l) z)))))

(defun flatten (l)
   (flatten2 l nil))

隐式堆栈操作被解释为变量之间的列表结构操作。

Answer 2

其实你们很亲近。正如 Sylwester 提到的，问题在于 (push el acc) 仅修改 el 的本地绑定（其中每次调用 rflatten。正如 Rainer 提到的，它并不是传统意义上的累加器，所以我不会称它为 acc，而是 result。既然你'已经定义了一个本地函数，没有理由不在更广泛的范围内定义 result：

(defun flatten (lst)
  (let ((result '()))
    (labels ((rflatten (lst1)
               (dolist (el lst1)
                 (if (listp el)
                   (rflatten el)
                   (push el result)))))
      (rflatten lst)
      (nreverse result))))

实际上也有几种方法可以清理它。第一个是风格和品味的问题，但我会使用 &aux 变量来绑定 result，所以

(defun flatten (lst &aux (result '()))
  ...)

接下来是dolist 可以接受第三个参数，一种用于评估返回值的形式。这通常用于“推送创建列表，然后反转返回值”的成语，例如，

(let ((result '()))
  (dolist (x list (nreverse result))
    ...
    (push ... result)))

您不想在每个 dolist 之后进行反转，但您仍然可以从 dolistreturn result >，因此来自 rflatten。然后你可以简单地用 rflatten 的结果调用 nreverse：

(defun flatten (lst &aux (result '()))
  (labels ((rflatten (lst1)
             (dolist (el lst1 result)
               (if (listp el)
                 (rflatten el)
                 (push el result)))))
      (nreverse (rflatten lst))))

Answer 3

push 更改范围内的符号绑定。因此，递归(rflatten el acc) 有它自己的acc，这是那里的结果，但你不对返回的结果做任何事情，它不会改变被调用者acc。

也许(setf acc (rflatten el acc)) 可以解决这个问题：

(defun flatten (lst)
  (labels ((rflatten (lst1 acc)
             (dolist (el lst1)
               (if (listp el)
                   (setf acc (rflatten el acc))
                   (push el acc)))
             acc))
    (reverse (rflatten lst nil))))