clojure 宏生成函数

Question

我正在尝试编写一个将生成 n 个函数的宏。这是我目前所拥有的：

; only defined this because if I inline this into make-placeholders
; it's unable to expand i# in  ~(symbol (str "_" i#))
(defmacro defn-from [str mdata args & body]
    `(defn ~(symbol str) ~mdata ~args ~@body))

; use list comprehension to generate n functions
(defmacro make-placeholders [n] 
    `(for [i# (range 0 ~n)] (defn-from  (str "_" i#) {:placeholder true} [& args] (nth args i#))))

; expand functions _0 ... _9
(make-placeholders 9)

我得到的错误是：

java.lang.ClassCastException: clojure.lang.Cons cannot be cast to java.lang.String

我不太确定这意味着什么，但我有一个模糊的概念，即 (for ...) 并没有像我认为的那样在宏中工作。

Answer 1

您对运行时和编译时以及宏和函数之间的区别感到困惑。用eval 解决宏问题永远不是¹ 正确的答案：相反，请确保返回的代码符合您的要求。这是使您的原始版本工作的最小更改。

主要变化有：

1. defn-from 是一个函数，而不是宏 - 您只需要一种方便的方法来创建列表，主宏负责将其插入结果表单。您确实不在此处需要宏，因为您不希望它扩展到make-placeholders 的正文中。

2. make-placeholders 以do 开头，并将其for 在语法引用之外。这是最重要的部分：您希望返回给用户的代码看起来像 (do (defn ...))，就好像他们是手动输入的一样 - 不是 (for ...)，这只能定义一个函数。

---

(defn defn-from [str mdata args & body]
    `(defn ~(symbol str) ~mdata ~args ~@body))

; use list comprehension to generate n functions
(defmacro make-placeholders [n]
  (cons `do
        (for [i (range 0 n)]
          (defn-from (str "_" i) {:placeholder true}
            '[& args]
            `(nth ~'args ~i)))))

user> (macroexpand-1 '(make-placeholders 3))
(do (clojure.core/defn _0 {:placeholder true} [& args] (clojure.core/nth args 0)) 
    (clojure.core/defn _1 {:placeholder true} [& args] (clojure.core/nth args 1)) 
    (clojure.core/defn _2 {:placeholder true} [& args] (clojure.core/nth args 2)))

¹非常非常罕见

---

编辑

您也可以完全不使用宏，通过使用函数来创建函数并使用较低级别的操作intern 而不是def。事实证明它要简单得多：

(letfn [(placeholder [n]
          (fn [& args]
            (nth args n)))]
  (doseq [i (range 5)]
    (intern *ns* (symbol (str "_" i))
            (placeholder i))))

Answer 2

在(make-placeholders 9) 表达式后进行宏扩展，我得到了这个：

(for
 [i__1862__auto__ (range 0 9)]
 (defn-from
     (str "_" i__1862__auto__)
     {:placeholder true}
   [& args]
   (nth args i__1862__auto__)))

所以defn-from 需要一个字符串作为第一个参数，但是，因为它是一个宏，(str "_" i__1862__auto__) 不会被评估，因此作为一个列表过去。

我玩了一段时间后想出了这个：

(defmacro make-placeholders [n]
  `(map eval
        '~(for [cntr (range 0 n)]
           `(defn ~(symbol (str "_" cntr))
               {:placeholder true} [& args] (nth args ~cntr)))))

宏扩展(make-placeholders 3) 给出

(map eval
 '((defn _0 {:placeholder true} [& args] (nth args 0))
   (defn _1 {:placeholder true} [& args] (nth args 1))
   (defn _2 {:placeholder true} [& args] (nth args 2))))

这是我的意图和评估这定义了函数 _0、_1 和 _2：

;=> (_0 1 2 3)
1
;=> (_1 1 2 3)
2
;=> (_2 1 2 3)
3

好的，所以这可行，但我仍然不确定这样做是否是个好主意。

首先eval is evil。好的，也可以不使用eval，而是使用do（在我的解决方案中将map eval 替换为do）。但是您可能使您的代码难以理解，因为您创建了未在代码中任何地方定义的函数。我记得当我刚开始使用 Clojure 时，我在某个库中寻找一个函数，但我找不到它。我开始想哎呀，这家伙一定在某个地方定义了一个宏来定义我正在寻找的函数，我怎么会理解发生了什么？如果这就是人们使用 Clojure 的方式，那么它将变得一团糟，而且人们所说的关于 Perl 的一切都相形见绌......原来我只是在看错误的版本 - 但你可能是让自己和他人承受一些困难。

话虽如此，这可能有适当的用途。或者您可以使用类似的东西来生成代码并将其放入某个文件中（然后源代码将可供检查）。也许有经验的人可以插话？