变量的行为不符合预期

Question

我一直在努力尝试使该批处理文件的语法正确，但我无法弄清楚为什么有些东西不起作用。

1. 变量i 不会在我每次执行此操作时递增。
2. strc 上的串联似乎没有串联。

这是我的代码：

set i=0
set "strc=concat:"

for %%f in (*.mp4) do (
    set /a i+=1
    set "str=intermediate%i%.ts"

    set strc="%strc% %str%|"

    ffmpeg -i "%%f" -c copy -bsf:v h264_mp4toannexb -f mpegts "%str%"
)

set strc="%strc:-1%"
ffmpeg -i "%strc%" -c copy -bsf:a aac_adtstoasc Output.mp4

Answer 1

你不是第一个掉入著名的“延迟扩张陷阱”的人（你也不会是最后一个）。

如果您想使用在同一个块中更改的变量，则需要延迟扩展（块是括号内的一系列命令(和)）。

延迟变量使用!var! 而不是%var% 引用。

原因是方式，cmd 解析代码。一次解析完整的行或块，在解析时用它们的值替换普通变量。延迟变量在运行时进行评估。

两个简单的批处理文件来演示：

setlocal EnableDelayedExpansion
set "var=hello"
if 1==1 (
    set "var=world"
    echo %var% !var!
)

setlocal EnableDelayedExpansion
for /L %%i in (1,1,5) do (
    echo %random% !random!
)

注意：一行也被视为一个块：

set "var=old"
set "var=new" & echo %var% 

延迟扩展：

setlocal EnableDelayedExpansion
set "var=old"
set "var=new" & echo !var! 

延迟扩展在命令提示符下默认关闭。如果你真的需要它，你可以这样做：

cmd /V:ON /C "set "var=hello" & echo !var!"

还有一种方法可以在不延迟扩展的情况下执行相同的操作（但 call 会花费一些时间，因此速度较慢，但​​如果由于某种原因您不能/不想使用延迟扩展，这是一种替代方法):

setlocal DISabledelayedexpansion
for /L %%i in (1 1 5) do (
    call echo %random% %%random%% 
)

这两种方法也可以用来显示array-like variables：

（这通常被称为“包含另一个变量的变量”或“嵌套变量”）

这是一个在不同情况下使用此类数组变量的集合：

延迟扩展：

setlocal ENableDelayedExpansion
set "num=4"
set "var[%num%]=HELLO"
echo plain delayed: !var[%num%]!
for /L %%i in (4 1 4) do (
    echo for delayed: !var[%%i]!
    set a=%%i
    call echo for delayed with variable: %%var[!a!]%%
)

没有延迟扩展：

setlocal DISableDelayedExpansion
set "num=4"
set "var[%num%]=HELLO"
call echo plain called: %%var[%num%]%%
for /L %%i in (4 1 4) do (
    call echo FOR called: %%var[%%i]%%
    set a=%%i
    call echo FOR called with variable: %%var[%a%]%%
)

注意：setlocal 在批处理文件之外没有任何作用，所以delayedexpansion 仅适用：

• 在批处理文件中
• 当 cmd 启动时启用延迟扩展 (cmd /V:ON)（默认情况下，cmd 运行时延迟扩展 disabled）

（如果您对technical background 甚至advanced technical stuff 感兴趣，请点击链接）