我如何制作这个脚本？

Question

我想要一个在 CMD 中使用这些选项的脚本：

wmic bios get serialnumber 

然后询问供应商，即。惠普或戴尔。
那么输出应该是类似于来自 wmic 的vendor-serialnumber，然后在序列号中添加一个 -，如下所示：

YHT3-1234 

“-”应始终位于序列号的最后 4 位数字之前，
所以最终的输出会是这样的：

HP-YHT3-1234

Answer 1

这是使用 PowerShell 获取它的另一种方法。除非您的组织禁止它，否则 PowerShell 可在所有受支持的 Windows 系统上使用。

FOR /F "delims=" %A IN ('powershell -NoLogo -NoProfile -Command ^
    "$x=Get-CimInstance CIM_BIOSElement;"
    "'{0}-{1}-{2}' -f"
    "@($x.Manufacturer, $x.SerialNumber.Substring(0,$x.SerialNumber.Length - 4),"
    "$x.SerialNumber.Substring($x.SerialNumber.Length - 4))"') DO (SET "RESULT=%A")
ECHO RESULT is %RESULT%

如果进入 .bat/.cmd 脚本，请记住将 PERCENT SIGN 字符加倍。

FOR /F "delims=" %%A IN ('powershell -NoLogo -NoProfile -Command ^
    "$x=Get-CimInstance CIM_BIOSElement;"
    "'{0}-{1}-{2}' -f"
    "@($x.Manufacturer, $x.SerialNumber.Substring(0,$x.SerialNumber.Length - 4),"
    "$x.SerialNumber.Substring($x.SerialNumber.Length - 4))"') DO (SET "RESULT=%%A")
ECHO RESULT is %RESULT%

Answer 2

这里有一个快速示例，向您展示如何在序列号中引入连字符/破折号，以及一些额外的工作来自动检测制造商，并根据需要缩短为标识符。

@Echo Off
SetLocal EnableExtensions
Set "Vendor="
Set "Serial="
For /F Tokens^=6^ Delims^=^" %%G In ('%SystemRoot%\System32\wbem\WMIC.exe BIOS Where "Manufacturer Like '%%Hewlett-Packard%%' Or Manufacturer Like '%%Dell%%' And SerialNumber Is Not NULL" Get Manufacturer^,SerialNumber /Format:MOF 2^>NUL') Do If Not Defined Vendor (Set "Vendor=%%G") Else Set "Serial=%%G"
If Not Defined Vendor GoTo :EOF
If "%Vendor:Dell=%" == "%Vendor%" (Set "Serial=HP-%Serial:~,-4%-%Serial:~-4%") Else Set "Serial=Dell-%Serial:~,-4%-%Serial:~-4%"
Echo %Serial%
Pause

显然，如果有很多制造商，则需要做额外的工作。

---

出于不必要的礼貌，这里是相同的方法，只是这次为最终用户提供了破解代码或破坏结果的机会：

@Echo Off
SetLocal EnableExtensions
Set "Serial="
For /F Tokens^=6^ Delims^=^" %%G In ('%SystemRoot%\System32\wbem\WMIC.exe BIOS Where "SerialNumber Is Not NULL" Get SerialNumber /Format:MOF 2^>NUL') Do Set "Serial=%%G"
If Not Defined Serial GoTo :EOF
Set /P "Vendor=Type the name of the Computer Manufacturer, and press ENTER>"
Echo %Vendor%-%Serial:~,-4%-%Serial:~-4%
Pause

---

基于对一台惠普笔记本和下面 KJ 的 cmets 的非常有限的测试，以下想法也可能有用：

@Echo Off
SetLocal EnableExtensions
Set "Serial="
Set "Vendor="
For /F Tokens^=2^,4^ Delims^=^" %%G In ('%SystemRoot%\System32\wbem\WMIC.exe
 CSProduct Assoc:List 2^>NUL') Do Set "Serial=%%G" & For /F %%I In ('
 %SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe -NoLogo -NoProfile
 "-Join '%%H'.ToUpper()[0..3]"') Do Set "Vendor=%%I" 
If Not Defined Serial GoTo :EOF
Echo %Vendor%-%Serial:~,-4%-%Serial:~-4%
Pause

这使用 PowerShell 仅从 WMIC 的 CSProduct 别名作为 Name 值返回的字符串中返回最多大写的前四个字符。所以Compaq 将返回COMP，Dell 作为DELL，Lenovo 作为LENO Samsung 作为SAMS 等等。然后这将作为序列号的前缀，（拆分为之前），在我的测试中作为 ComputerSystemProduct IdentificationNumber 返回。