如何将文本文档批量拆分为变量

Question

所以我想知道是否有一种方法可以让批处理文件读取单独的文本文档并将特定的代码行转换为具有相同值的变量，就像来自文档一样。所以让批处理脚本读取文本文档，并使用其中的信息来创建它自己的变量。 例如。

TEXT.txt：

test==a
test2==b
test3==c

然后批处理脚本会读取该文本并将其转换为与 TEXT.txt 文档中给出的值相同的可用变量

像这样： 可用的批处理变量：

%test% is "a"
%test2% is "b"
%test3% is "c"

等等

此外，批处理文件是否可以使用set /p opt= Userinput: 读取用户输入，然后获取用户输入并将输入的每个字母转换为单独的单独变量？

例如。 当提示set /p opt= Userinput: 时，用户输入：“hello”，批处理脚本将用户输入转换为：

%letter1% is "h" 
%letter2% is "e" 
%letter3% is "l"
%letter4% is "l"
%letter5% is "o"

批处理脚本是否也可以读取用户输入中的空格，例如用户输入是“大家好”，然后批处理脚本会说

%letter1% is "h"
%letter2% is "i" 
%letter3% is "0" 
%letter4% is "a" 
%letter5% is "l" 
%letter6% is "l"

Answer 1

要获取示例 TEXT.txt 中显示的内容，您可以使用 For /F 循环并使用 = 字符作为分隔符：

@For /F "Tokens=1*Delims==" %%G In ('find "=" ^<"TEXT.txt"')Do @Set "%%G=%%H"

不过，我不想依赖%PATH% 和%PATHEXT%：

@For /F "Tokens=1,* Delims==" %%G In ('%SystemRoot%\System32\find.exe "="
 0^<"TEXT.txt"') Do @Set "%%G=%%H"

---

至于您更有趣的问题，下面的batch-file 尝试将用户输入的每个字符保存到单独的变量中。

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion

:GetInput
Set "Input="
Set /P "Input=Enter your string here>"
If Not Defined Input GoTo GetInput
For /F "Delims==" %%G In ('"(Set Char[) 2> NUL"') Do Set "%%G="
Set "i=0" & For /F Delims^=^ EOL^= %%G In ('(%SystemRoot%\System32\cmd.exe /V /U
 /S /D /C "(Echo=!Input!)"^) ^| %SystemRoot%\System32\find.exe /V ""') Do (
    Set /A i += 1 & SetLocal EnableDelayedExpansion
    For %%H In (!i!) Do EndLocal & Set "Char[%%H]=%%G")

(Set Char[) 2>NUL
Pause

添加最后两行只是为了给您一些已完成的视觉反馈，您显然会在那里使用自己的代码......