递归调用中的 echo %%~fF 和 echo %%~fF >> file.txt 有什么区别

Question

我想列出具有给定嵌套级别的子目录。控制台显示工作正常，但是在将相同的回显附加到文件时，它的行为会有所不同。

@echo off
setlocal

set currentLevel=0
set maxLevel=%1
if not defined maxLevel set maxLevel=1
 
:procFolder
pushd %1 2>nul
if %currentLevel% lss %maxLevel% (
  for /d %%F in (*) do (
    echo %%~fF
    echo %%~fF >> list.txt
    set /a currentLevel+=1
    call :procFolder "%%F"
    set /a currentLevel-=1
  )
)
popd

使用参数 3 调用批处理文件会写入预期嵌套三个子文件夹的 shell

D:\erroronline1\code\learntoshell\sub1
D:\erroronline1\code\learntoshell\sub1\sub2
D:\erroronline1\code\learntoshell\sub1\sub2\sub3

但在实际文件中只写了第一级递归

D:\erroronline1\code\learntoshell\sub1

这发生在所有可能的子文件夹中，只是附加了第一级嵌套。 我无法使用其他列出子目录的方法来控制嵌套级别（对于 /r %%F in (.), dir /s），因此这不会作为一个选项出现。 暂停递归（等待文件被写入，无论如何）或将文件夹传递给变量也没有帮助。

我错过了什么？递归调用中的 echo 和 echo >> 文件有什么区别？

Answer 1

pushd 改变当前目录。 重定向的回显输出附加到当前目录中的文件中。

将日志文件从当前目录更改为完整路径，您将在一个文件中获取所有日志记录，而不是嵌套目录中的多个文件。

Answer 2

您可以使用robocopy 实用程序将事情简化为两行batch-file：

示例：通过传递两个参数来运行它，第一个是您的目录，第二个是您的级别数，例如test.cmd "%UserProfile%\Downloads" 3

@Set /A Levels = %~2 + 1
@"%__APPDIR__%Robocopy.exe" "%~1" "%~1" /E /L /LEV:%LEVELS% /NC /NS /NFL /NJH /NJS 1> "list.txt"

而且，如果你真的不想要前导空格：

@Set /A Levels = %~2 + 1
@(For /F Tokens^=* %%G In ('%__APPDIR__%Robocopy.exe "%~1" "%~1" /E /L /LEV:%LEVELS% /NC /NS /NFL /NJH /NJS 2^> NUL') Do @Echo %%G) 1> "list.txt"

[编辑/]

根据您的评论，这里只修改了一个参数，即test.cmd 3，（使用当前目录作为基础）。

@Set /A Levels = %~1 + 1
@"%__APPDIR__%Robocopy.exe" . . /E /L /LEV:%LEVELS% /NC /NS /NFL /NJH /NJS 1> "list.txt"

并且，再次没有前导空格：

@Set /A Levels = %~1 + 1
@(For /F Tokens^=* %%G In ('%__APPDIR__%Robocopy.exe . . /E /L /LEV:%LEVELS% /NC /NS /NFL /NJH /NJS 2^> NUL') Do @Echo %%G) 1> "list.txt"

请确保，如果这是重要的，首先检查有效的输入参数。