使用 for 循环等待进程在远程 PC 上终止

Question

应该能够对此进行排序，但我正在兜圈子。我知道这与 setlocal 有关 EnableDelayedExpansion，但我错过了一些东西。

目标： 在远程机器上执行 windows (cleanmgr.exe) 脚本，等到 Cleanmgr.exe 关闭然后有 启动脚本从远程“输入”生成的日志文件（通过清理脚本生成） 系统在 CMD 窗口中。

什么有效： 在远程机器上运行的脚本运行良好，它将 C: free drive space 回显到日志文件中， 然后清理PC，然后重新运行磁盘空间报告并将结果回显到同一日志文件中， 因此用户可以通过前后结果看到（/具有透明度）回收空间。

什么是坏的： 在目标 PC 上检查 Cleanmgr.exe 的 WMIC 命令仅在等待重试时有效 包含主机名的变量已被清除。我可以通过回显来查看行为 变回。

修复尝试： 我有一种预感，这与 if 语句在 括号。我尝试了很多选项，但它们的行为都相同。我试过跳 使用 %1 而不是 %%i 处理在原始代码之外循环，但不能完全到达那里。

感谢您的改进。

@echo off
pushd %~dp0
color 1e
setlocal EnableDelayedExpansion
title HDD Space Checker...
for /f %%i in (hostnames.txt) do (
xcopy /y cleanupwindows-sfd.bat \\%%i\C$\IT
WMIC /node:"%%i" process call create "C:\IT\cleanupwindows-sfd.bat"
echo Waiting For Processes...
timeout -t 10 /nobreak >nul
:loop
WMIC /node:"%%i" process where name="cleanmgr.exe" get name |find "cleanmgr.exe">nul
IF "!errorlevel!"=="0" set running=var
IF "!running!"=="var" timeout -t 4 >nul & echo Still Running & goto :loop
IF "!running!"=="" timeout -t 4 >nul & type \\%%i\C$\IT\%%i_HHD_Space.log
)
pause
exit

Answer 1

至少有两点可看。

1. 您的 running 变量一旦设置，就永远不会重置，从而触发无限循环
2. 您在括号内的goto 语句会驱动命令解释器 (cmd.exe) 停止评估该块，因此您的脚本会松开 %%i 并离开 for 循环，因此在终止 :loop 时循环您的脚本将离开 for 循环而不循环到 hostnames.txt 中的其他值。

要解决这个问题，请将您的流程代码放入以CALL 调用的子例程中，并在每个:loop 循环中重置running 变量：

@echo off
pushd %~dp0
color 1e
setlocal EnableDelayedExpansion
title HDD Space Checker...
for /f %%i in (hostnames.txt) do (
  CALL:Process "%%i"
)
pause
exit
:Process
xcopy /y cleanupwindows-sfd.bat \\%~1\C$\IT
WMIC /node:"%~1" process call create "C:\IT\cleanupwindows-sfd.bat"
echo Waiting For Processes...
timeout -t 10 /nobreak >nul
:loop
set "running="
WMIC /node:"%~1" process where name="cleanmgr.exe" get name |find "cleanmgr.exe">nul
IF "!errorlevel!"=="0" set "running=var"
IF "!running!"=="var" timeout -t 4 >nul & echo Still Running & goto :loop
IF "!running!"=="" timeout -t 4 >nul & type \\%~1\C$\IT\%~1_HHD_Space.log
GOTO:EOF

说明：CALL 语句意味着命令解释器将在执行关联的子进程/命令/等之前存储脚本的当前执行行及其状态。当子进程/命令/等完成时，命令解释器使用恢复的上下文继续执行脚本到下一行。这避免了 for 循环上下文的松散。