OPENSSL_ia32_rdrand cmp/cmove 指令

Question

我试图了解 OpenSSL 中使用的 x86 汇编函数，以使用 CPU 的 RDRAND 指令获取随机字节。这是函数体：

OPENSSL_ia32_rdrand:
    mov     $8,%ecx
.Loop_rdrand:
    rdrand  %rax
    jc      .Lbreak_rdrand
    loop    .Loop_rdrand
.Lbreak_rdrand:
    cmp     $0,%rax
    cmove   %rcx,%rax
    ret

我无法弄清楚 cmp 和 cmove 指令的用途。我不是 x86 汇编程序员，但从我看过的参考资料中可以看出，我对它在做什么的理解是：

10 load retry counter to ecx
20 get random number into rax
30 if successful (carry flag set) goto 50
40 decrement counter and goto 20 if not zero
50 check if rax is zero
60 if it is, move rcx to rax
70 return 

因此，如果 rdrand 失败（进位标志清零），rax 只能为 0，并且只有在 1) rdrand 成功（进位集）并且在 rax 中放入非零数或 2 时才能到达 cmp 指令) ecx 中的重试计数器已减为 0。在情况 1 中，cmp 失败并且 cmove 不执行移动。在情况 2 中，rcx 包含 0，cmove 将 0 移动到 0。无论哪种方式，cmove 都是空操作。

我是否误解了一个或多个汇编指令的作用？

Answer 1

不只是你有轻微的误会。编写此程序的人不知道他们在做什么（嗯，您说的是 OpenSSL……真是令人惊讶）。英特尔的软件开发者手册推荐：

#define SUCCESS 1
#define RETRY_LIMIT_EXCEEDED 0
#define RETRY_LIMIT 10

int get_random_64( unsigned __int 64 * arand)
{
int i ;
for ( i = 0; i < RETRY_LIMIT; i ++)
    {
        if(_rdrand64_step(arand) ) return SUCCESS;
    }
return RETRY_LIMIT_EXCEEDED;
}

经过一些小改动让它在 gcc 上编译后，我得到：

get_random_64:
    movl    $10, %edx
    movl    $1, %ecx

.L3:
    rdrand  %rax
    movq    %rax, (%rdi)
    cmovb   %ecx, %eax
    testl   %eax, %eax
    jne .L4
    subq    $1, %rdx
    jne .L3
    rep ret
.L4:
    movl    $1, %eax
    ret

当rdrand() 随机生成它时，这实际上将返回一个零，而不是在这种情况下返回一个小的非零整数。我想说一个不能返回 0 并且返回 1 到 8 之间整数的概率略有增加的随机函数在设计上是有缺陷的，因为它的输出是有偏差的。

Answer 2

你有点误会了。

您的主要部分是正确的，有 8 次尝试使用 RDRAND 检索随机数，但如果 RDRAND 返回 0 作为 随机数，CMOVE 不一定是 NOP。在这种情况下，此函数将返回 RCX（循环计数）的值作为“随机数”。简而言之，此函数仅在没有可用随机数时返回 0 - 否则它将返回来自 RDRAND 的真实随机数或从 RDRAND 收到 0 的迭代数。