Delphi Pascal XE4 编译器错误？

Question

我想知道我是否发现了一个 Embarcadero 编译器错误......

这个问题看起来和泛型有关。

这是我的源代码

unit u_DateCount;

interface

uses
  SysUtils,
  u_JavaScriptable
  ;

type
  TDateCount = class (TJavaScriptable)
    strict private
    public
      NoOfSamples : Integer;
      TheDate : TDate;
      function ToString():String; override;
  end;

implementation

function TDateCount.ToString():String;
var
    myYear, myMonth, myDay : Word;
begin
    DecodeDate(TheDate, myYear, myMonth, myDay);
    Result := Format('[new Date(%d, %d ,0), %d]', [myYear, myMonth, NoOfSamples]);
end;

end.

---

unit u_Javascriptable;

interface

type
  TJavaScriptable = class
    strict private
    public
      function ToString:String; override;
  end;

implementation

function TJavaScriptable.ToString:String;
begin
    Result := '';
end;

end.

---

unit u_LineChart;

interface

uses
  System.IOUtils,
  SysUtils,
  System.Generics.Collections,
  u_JavaScriptable
  ;

type
  TLineChart<RecordType : TJavaScriptable> = class
    strict private
      Template : String;
      function ConvertRecordsToString():String;
    public
      Records : TList<RecordType>;
      function ToString():String;
      constructor Create(templatePath : String);
      destructor Destroy(); override;
  end;

implementation

function TLineChart<RecordType>.ConvertRecordsToString():String;
var
    I: Integer;
begin
    //Open brackets
    Result := '[ ';

    //The first record
    if Records.Count > 0 then
    begin
        Result := Result + Records[0].ToString();
    end;

    //Loop over records
    for I := 1 to Records.Count - 1 do
    begin
        Result := Result + ', ' + Records[I].ToString();
    end;

    //Close bracket
    Result := Result + ' ]';
end;

function TLineChart<RecordType>.ToString():String;
begin
    Result := Format(Template, [ConvertRecordsToString()]);
end;

constructor TLineChart<RecordType>.Create(templatePath : String);
begin
    inherited Create();
    Template := TFile.ReadAllText(templatePath);
    Records := TList<RecordType>.Create();
end;

destructor TLineChart<RecordType>.Destroy();
var
    I: Integer;
begin
    if Assigned(Records) then
    begin
        for I := 0 to Records.Count - 1 do
        begin
            Records[I].Destroy();
        end;
        Records.Clear();
        Records.Destroy();
        Records := nil;
    end;

    inherited;
end;

end.

---

最后是主程序

program Project4;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  u_Javascriptable in 'u_Javascriptable.pas',
  u_LineChart in 'u_LineChart.pas',
  u_DateCount in 'u_DateCount.pas';

var
   lineChart : TLineChart<TDateCount>;

begin

  lineChart := TLineChart<TDateCount>.Create('linechart.html');
  try


  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

---

我尝试编译时收到的错误消息是

[dcc32 致命错误] Project4.dpr(30): F2084 内部错误: AV097530AC-R00000014-0

通常当我看到与此类似的错误消息时，我可以通过关闭 embarcadero IDE 并重新启动它来修复它。但是，这一次似乎不起作用。

Answer 1

问题在于TLineChart<RecordType>.Destroy()的实现。

将 Records[I].Destroy(); 更改为 Records[I].Free(); 即可。 或者你只是做正确并在构造函数中使用TObjectList<RecordType>.Create;，它负责在销毁列表时销毁其中的所有元素。

切勿直接致电Destroy。使用Free。虽然它不应该导致编译器错误，但无论如何它都是错误的。

Answer 2

如果编译器报告“内部错误”，则始终是编译器错误。您应该为此在 QC 中打开一张票。希望他们可以为 XE5 修复它。

Answer 3

由于这适用于 XE3 而不是 XE4，我将假定这是一个 XE4 错误。在解决此问题之前，解决方案是使用不同版本的编译器，例如 XE3。