Lisp 中的 (list nil) 和 '(nil) 有什么区别？ [复制]

Question

首先，让我说我是 Lisp 的初学者。说实话，我初学者也有一段时间了，但还是有很多东西不是很了解。

在我写this question 的时候，我在我的代码中发现了一个奇怪的错误。

这是一个函数，它将返回列表(0 1 ... n)，并附加列表e。它一路使用rplacd 来跟踪最后一个元素，以避免最终调用last。

例如，(foo 4 '(x)) 返回(0 1 2 3 4 x)。

“头”存储在a，而不是简单的nil，因为只有一个nil，而且从来没有它的副本（如果我理解正确的话），所以我不能简单地追加到nil。

(defun foo (n e)
    (let* ((a (list nil)) (tail a))
        (loop for i to n
              do (rplacd tail (setf tail (list i)))
              finally (rplacd tail (setf tail e))
              (return (cdr a)))))

(defun bar (n e)
    (let* ((a '(nil)) (tail a))
        (loop for i to n
              do (rplacd tail (setf tail (list i)))
              finally (rplacd tail (setf tail e))
              (return (cdr a)))))

这些函数之间的唯一区别是bar 中的(list nil) 替换为'(nil)。虽然 foo 按预期工作，但 bar 始终返回 nil。

我最初的猜测是发生这种情况是因为a 的原始cdr 确实是nil，并且引用的列表可能被认为是不变的。但是，如果我执行(setf x '(nil)) (rplacd x 1)，我会按预期得到(nil . 1)，所以我必须至少部分错误。

Answer 1

引用的数据被认为是一个常数。如果你有两个功能：

(defun test (&optional (arg '(0)))
  (setf (car arg) (1+ (car arg)))
  (car arg))

(defun test2 ()
  '(0))

这两个函数都使用常量列表(0) 对吗？

1. 实现可以选择不改变常量：

   (test) ; ==> Error, into the debugger we go
   

2. 实现可以cons同一个列表两次（读者可能会这样做）

   (test2) ; ==> (0)
   (test)  ; ==> 1
   (test)  ; ==> 2
   (test)  ; ==> 3
   (test2) ; ==> (0)
   

3. 实现可以看到它是相同的，并且可以节省空间：

   (test2) ; ==> (0)
   (test)  ; ==> 1
   (test)  ; ==> 2
   (test)  ; ==> 3
   (test2) ; ==> (3)
   

事实上。最后两种行为可能发生在同一实现中，具体取决于正在编译的函数。

在 CLISP 中，这两个函数的工作方式相同。我还看到在使用 SBCL 反汇编时，该常量实际上已经发生了变异，所以我想知道它是否在编译时有常量折叠 (cdr '(0)) 并且根本不使用变异列表。这真的没关系，因为两者都被认为是好的“未定义”行为。

from CLHS关于这个的部分很短

如果字面量对象（包括引用 对象）被破坏性修改。

Answer 2

在评估时，'(nil) 和 (list nil) 会产生相似的列表，但前者在源代码中存在时可被视为常量。您不应该对 Common Lisp 中的常量引用列表执行任何破坏性操作。请参阅 http://l1sp.org/cl/3.2.2.3 和 http://l1sp.org/cl/quote。特别是，后者说“如果文字对象（包括引用的对象）被破坏性地修改，后果是不确定的。”