简单的线程示例 Delphi

Question

我对 Delphi 中的线程处理这个东西很陌生。所以，我正在尝试制作一个简单的查询应用程序，它会调用数据库并花费一些时间，所以我想提醒用户有一个后台进程并且必须耐心等待。

我尝试了很多示例，但没有一个对我有用，请问有人可以给我看一个可以工作的简单示例吗？

我知道我必须声明一种 TThread 类型，使用 Create 和 Override Execute... 等等。但是因为我迷路了...

使用 Delphi 7、SQL Server 2005 和 ADO、Windows XP sp3.-

谢谢。

Answer 1

是的，你声明了一个继承自 TThread 的新类型：

TMyWorkerThread = class(TThread)
end;

然后为 Execute() 添加一个函数覆盖：

TMyWorkerThread = class(TThread)
public
  procedure Execute; override;
end;

启动线程时将调用该过程。它将与您的主程序并行执行。我们来写吧。

procedure TMyWorkerThread.Execute;
begin
  //Here we do work
   DoSomeWork();
   DoMoreWork();
  //When we exit the procedure, the thread ends.
  //So we don't exit until we're done.
end;

这个怎么用？假设您想在用户单击按钮时开始工作。你编写一个 OnClick 处理程序：

procedure TMainForm.Button1Click(Sender: TObject);
begin
  TMyWorkerThread.Create(false);
end;

就是这样。用户单击按钮后，您的线程将启动并继续执行您在 Execute 中编写的任何操作。如果用户再次单击该按钮，则会启动另一个线程，然后再启动另一个线程 - 每次单击都会启动一个。它们都将并行运行，每个都执行 Execute() 中编写的所有操作，然后结束。

假设您想检查工作是否结束。为此，您必须将对线程的引用存储在某处：

TMainForm = class(TForm)
{...skipped...}
public
  MyWorkerThread: TThread;
end;

procedure TMainForm.Button1Click(Sender: TObject);
begin
  //This time we make sure only one thread can be started.
  //If one thread have been started already, we don't start another.
  if MyWorkerThread<>nil then
    raise Exception.Create('One thread have already been started!');
  MyWorkerThread := TMyWorkerThread.Create(false);
end;

procedure TMainForm.Button2Click(Sender: TObject);
begin
  //If the work is not over yet, we display message informing the user we're still working
  if (MyWorkerThread<>nil) and (WaitForSingleObject(MyWorkerThread.Handle, 0)<>WAIT_OBJECT_0) then
    MessageBox(Self.Handle, pchar("The work is not yet done!"), pchar("Still running"), MB_OK);
end;

如您所见，我们通过调用称为 WaitForSingleObject 的 Windows 函数来检查线程是否仍在运行。这个函数会一直等待，直到线程完成工作，或者超时时间已经过去，并且我们指定超时时间为 0，如果线程还没有结束，它就立即存在。

Answer 2

您可以在线程网络上找到许多示例。如果您在 Thread 中使用 ADO 连接，唯一的特殊功能是您不能共享同一个连接。
每个线程必须创建自己的连接，否则它们是平等的（应该遵循与任何其他线程相同的规则。）

我使用的一个示例是这样的：

  TADOSQLThread = class(TThread)
  private
    FADOQ: TADOQuery;  // Internal query
    FSQL: string;      // SQL To execute
    FID: integer;      // Internal ID

  public
    constructor Create(CreateSuspended:Boolean; AConnString:String;
                       ASQL:string; IDThread:integer);
    destructor Destroy; override;
    procedure Execute(); override;

    property ID:integer read FID write FID;
    property SQL:string read FSQL write FSQL;
    property ADOQ:TADOQuery read FADOQ write FADOQ;
  end;

Create 构造函数被覆盖，如下所示：

constructor TADOSQLThread.Create(CreateSuspended:Boolean; AConnString:String;
                                 ASQL:string; IDThread:integer);
begin

  inherited Create(CreateSuspended);

  // ini
  Self.FreeOnTerminate := False;

  // Create the Query
  FADOQ := TAdoquery.Create(nil);
  // assign connections
  FADOQ.ConnectionString := AConnString;
  FADOQ.SQL.Add(ASQL);
  Self.FID := IDThread;
  Self.FSQL:= ASQL;
end;

而且执行方法很简单：

procedure TADOSQLThread.Execute();
begin

  inherited;

  try
    // Ejecutar la consulta
    Self.FADOQ.Open;
  except
    // Error al ejecutar
    ...Error treattement
  end;
end;

要启动和创建线程，您可以使用类似以下的代码：

  //crear el Thread
  th := TADOSQLThread.Create(True, mmConnection.Lines.Text, ASQL, AId);
  // internal for me (for controled the number of active threads and limete it)
  inc(numThreads);
  // evento finalizacion
  th.OnTerminate := TerminateThread;
  // Ejecutarlo
  th.Resume;

我创建了一个 TerminateThread 方法，该方法在线程完成时接收线程控制。与其他线程唯一不同的是连接问题。您必须在每个线程上创建一个新连接，它不能与其他线程共享相同的 ADOConnection。
我希望这个例子对你有用。

问候