使用来自 vb.net 的随机数自动更新访问表单元格

Question

我搜索了很多论坛，但没有找到任何解决方案。我想从 Vb.net 更新访问表格单元格。我的表有字段：

[PanelNumber],[Date], [PVValue]

在面板编号字段中，有一些文本，如“面板 1”、“面板 2”等。 从vb，我将在单击按钮后选择“面板1”，我需要用给定范围内的随机数填充“PVValue”字段，请检查下面的代码，当我尝试使用此代码时，我总是得到相同所有行中的数字 但需要单独的数字（可能在某些行中重复） LogTable2 是我的表名

Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        connString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=LoggedData.accdb;Jet OLEDB:Database Password=GodavarthiSuresh;"
        myNewConnection.ConnectionString = connString
        myNewConnection.Open()

        Dim UpdateString As String = "update LogTable2 set [pvvalue]= @rndVal1 where panelnumber='" & panelnametxt.Text & "'"
        Dim UpdateCmd As New OleDb.OleDbCommand(UpdateString, myNewConnection)
        UpdateCmd.Parameters.Clear()
        Randomize()
        UpdateCmd.Parameters.AddWithValue("@rndVal1", GetRandom())

        Try
            UpdateCmd.ExecuteNonQuery()
            UpdateCmd.Dispose()
            myNewConnection.Close()

        Catch ex As Exception
            MsgBox(ex.Message)
        End Try


    End Sub
' this is the function to get random number in given range
 Public Function GetRandom() As Integer
        Static Generator As System.Random = New System.Random()
        Return Generator.Next(825, 850)
    End Function

Answer 1

您可以在数据库级别执行此操作，将自动增量值添加到数据库字段

Answer 2

如果每个面板有多个行并且希望它们具有不同的值，则需要单独更新它们。如果有五行关联，更新命令将被“调用”5 次是不正确的。每次点击事件都会执行一次。

要做到听起来像你想要的，你需要一个唯一的标识符，例如 AutoIncrement ID 列。

Private RNG As New Random()
Private Sub btnUpdate_Click(etc...

    Dim sql = "SELECT ID FROM LogTable2 WHERE panelnumber = @pnl"
    Dim pnlList As New List(Of Int32)

    Using con As OleDbConnection = GetACEConnection()
        Using cmd As New OleDbCommand(sql, con)

            con.Open()

            cmd.Parameters.AddWithValue("@pnl", panelnametxt.Text)

            ' get affected row IDs into a list;
            Using rdr As OleDbDataReader = cmd.ExecuteReader
                While rdr.Read
                    pnlList.Add(Convert.ToInt32(rdr.Item("ID")))
                End While
            End Using           ' close, dispose of reader
        End Using               ' dispose of cmd

        ' not sure you need a new command object
        sql = "UPDATE LogTable2 SET pvvalue = @rVal WHERE ID = @id"

        Using pcmd As New OleDbCommand(sql, con)
            ' loop thru ID list and update each row with
            ' new random value 825-849 inclusive
            For n As Int32 = 0 To pnlList.Count - 1
                pcmd.Parameters.AddWithValue("@rVal", RNG.Next(825, 850))
                pcmd.Parameters.AddWithValue("@id", pnlList(n))
                pcmd.ExecuteNonQuery()
                ' clear for next iteration
                pcmd.Parameters.Clear()

            Next
        End Using                  ' close and dispose of pcmd
    End Using                      ' close and dispose of connection

End Sub

我不喜欢在每个打开连接的方法中分散连接字符串，所以a method for that 很高兴。

注意事项：

• 这取决于唯一的 ID 列，即 AutoIncrement (PK)。如果您有其他唯一标识符，请使用它，但您必须有某种方法来单独识别行。
• 而不是创建随机值的方法，因为它只有一行，直接使用 RNG 可能更容易，如图所示。
• 我无法测试代码，但应该很接近。
• 使用Using 块来关闭和处理连接、命令和读取器等 DBObject，否则可能会耗尽资源。
• 您还可以在声明Command 对象时使用SQL 和CONnection 对其进行初始化，而不是将它们设置为属性。它使代码更加紧凑，并且您不太可能忘记它们。
• Randomize 什么都不做 - 它旨在与旧的 VB6 Rnd() 一起使用。 SQL中只需要[Escape]关键字，不是每个列名，pvvalue不是关键字。
• 可以使用DataTable 而不是Reader 来获取行，但我不确定它是否更简单。
• 最后，SQL WHERE 子句的元素也可以参数化；无需仅仅因为它是 where 而不是列值而将它们连接起来。