如何将excel打印到PDF，不包括第一张纸

Question

我正在尝试将 Excel 工作簿打印为 pdf，但从 PDF 中排除标题为基本信息的第一张工作表。目前整个工作簿都包含在 PDF 中

Option Explicit

Sub CreatePDF()
  Dim IsCreated As Boolean
  Dim PdfFile As String, Title As String
  Dim s As Worksheet
  Dim DoNotInclude As String

  With Application
    .DisplayAlerts = False
    .ScreenUpdating = False
  End With

  Title = "I&T Plan for " & Worksheets("Basic Information").Range("C7").Value
  PdfFile = CreateObject("WScript.Shell").SpecialFolders("Desktop") & "\" & Title & ".pdf"
  
    Sheets("Front Sheet").Select
   
  
  DoNotInclude = ("Basic Information")
  
    For Each s In ActiveWorkbook.Worksheets
    If s.Visible = True Then
      If InStr(DoNotInclude, s.Name) = 0 Then
          s.Select (False)
      End If
    End If
  Next

  With ActiveSheet
    .ExportAsFixedFormat Type:=xlTypePDF, fileName:=PdfFile, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
  End With

  Sheets("Front Sheet").Select

  MsgBox "Created PDF file on the desktop", vbOKOnly, "I&T PDF"

  With Application
    .DisplayAlerts = True
    .ScreenUpdating = True
  End With


End Sub

Answer 1

选择除第一张以外的所有工作表：

Dim x As Long, wb As Workbook
    
Set wb = ActiveWorkbook
wb.Sheets(2).Select
For x = 3 To Sheets.Count
    wb.Sheets(x).Select False
Next x

打印...

Answer 2

将多个工作表导出为 PDF

• 有趣的事实：如果您选择“基本信息”以外的任何工作表，您的代码将按要求工作。您必须考虑到当前选择的（活动）工作表最终会出现在选择中。

不关心选择了哪个工作表或工作表的位置（索引），您可以使用：

Dim arr As Variant: ReDim arr(1 To ActiveWorkbook.Worksheets.Count)
Dim n As Long
For Each s In ActiveWorkbook.Worksheets
  If s.Visible = True Then
    If InStr(1, DoNotInclude, s.Name, vbTextCompare) = 0 Then
        n = n + 1
        arr(n) = s.Name
    End If
  End If
Next
ReDim Preserve arr(1 To n)
ActiveWorkbook.Worksheets(arr).Select

字里行间：

DoNotInclude = "Basic Information"

和

With ActiveSheet