用替换合并SAS中的两个不相等的数据集答案

【问题标题】：Merge two unequal data sets in SAS with replacment用替换合并SAS中的两个不相等的数据集
【发布时间】：2021-06-14 05:13:25
【问题描述】：

我在 SAS 中生成了倾向得分，以匹配两个不相等的组并进行替换。现在我正在尝试创建一个数据集，其中两组的观察次数相同 - 即组 b 中应该有重复的观察，因为那是较小的组。下面我有合成数据来证明我想要得到什么。

Indicator Income  Matchid
1         7       1
1         8       2
1         4       1
0         6       1
0         9       2

我希望它看起来像这样

Indicator Income  Matchid
1         7       1
1         8       2
1         4       1
0         6       1
0         9       2
0         6       1

【问题讨论】：

请 1) 添加您的输入，而不仅仅是您的输出 2) 向我们展示您的尝试

标签： merge sas propensity-score-matching

【解决方案1】：

在视图中，您可以创建一个变量，该变量是一个可以进行模数评估的组序列号。在数据步骤中，将两个指标组加载到单独的散列中，然后针对每个循环在最大组大小上进行选择，按索引模数组大小进行选择。

例子：

data have;
input Indicator Income  Matchid;
datalines;
1         7       1
1         8       2
1         4       1
0         6       1
0         9       2
;

data have_v;
  set have;
  by indicator notsorted;
  if first.indicator then group_seq=0; else group_seq+1;
run;


data want;
  if 0 then set have_v;

  declare hash i1 (dataset:'have_v(where=(indicator=1))', ordered:'a');
  i1.defineKey('group_seq');
  i1.defineData(all:'yes');
  i1.defineDone();

  declare hash i0 (dataset:'have_v(where=(indicator=0))', ordered:'a');
  i0.defineKey('group_seq');
  i0.defineData(all:'yes');
  i0.defineDone();

  do index = 0 to max(i0.num_items, i1.num_items)-1;
    group_seq = mod(index,i1.num_items);
    i1.find();
    output;
  end;

  do index = 0 to max(i0.num_items, i1.num_items)-1;
    group_seq = mod(index,i0.num_items);
    i0.find();
    output;
  end;

  stop;

  drop index group_seq;
run;

如果将两个组分成数据集，您可以使用SET 选项nobs= 和point= 进行类似的处理

【讨论】：