宏 Do 循环在 RSUBMIT 中无法正常工作

Question

所以我有这段代码可以正常运行一年，但我需要将其转换为循环，以便它可以在 1970 年到 2015 年之间运行多年。

这是我在 %let 语句中指定的 1 年代码。

%let year=1970
rsubmit; 
data home.historical_returns_&year;
set home.crspdata;
where (year <= &year - 1) and (year >= &year - 5);
returns_count + 1;
by id year;
if first.id or missing(tot_ret) then returns_count = 1;
run;
endrsubmit;

到目前为止，该代码对我来说非常有用。现在，我正在尝试使用循环，所以我会在 1970 年到 2015 年期间使用它。

我想出了这个。看起来效果不错，但年份停留在 1970 年。

%macro GMV;
rsubmit;
%do year=1970 %to 2015;
data home.historical_returns_&year;
set home.crspdata;
where (year <= &year - 1) and (year >= &year - 5);
returns_count + 1;
by id year;
if first.id or missing(tot_ret) then returns_count = 1;
run;
%end;
endrsubmit;

%mend GMV;

%GMV

在日志中，我看到名称中的 &year 实际上从未从 1970 年到 1971 年到 1972 年等发生变化。所以我最终没有得到我需要的 45 个不同的数据集。

有人遇到过这个问题吗？

谢谢！

Answer 1

您将远程处理与本地处理混为一谈，这会导致此类问题。你的宏变量不会被更新（我有点惊讶它没有抛出关于 %do 循环的错误，就个人而言）。

rsubmit;

%macro GMV;
%do year=1970 %to 2015;
data home.historical_returns_&year;
set home.crspdata;
where (year <= &year - 1) and (year >= &year - 5);
returns_count + 1;
by id year;
if first.id or missing(tot_ret) then returns_count = 1;
run;
%end;

%mend GMV;

%GMV
endrsubmit;

将整个宏放入 rsubmit 以获得您正在寻找的结果 - 或将整个 rsubmit 放入宏中（我认为这不是一个好主意，尽管 cmets 中的 Tom 指出它可能更安全某些情况下的选项）。

Answer 2

如果您想在RSUBMIT 的代码中引用宏变量，那么该宏变量需要存在于远程会话中。

%macro GMV(start,end);
   %local year;
   %do year=&start %to &end;
      %syslput year=&year;
      rsubmit;
       data home.historical_returns_&year;
         set home.crspdata;
         by id year;
         where (year <= &year - 1) and (year >= &year - 5);
         returns_count + 1;
         if first.id or missing(tot_ret) then returns_count = 1;
       run;
     endrsubmit;
   %end;
 %mend GMV;

 %GMV(1970,2015);