我在表单上有以下按钮：
Private Sub CommandButton1_Click()
Dim pass As String
pass = UserForm1.TextBox1
Unload UserForm1
End Sub
然后我有一个名为 Module1 的模块：
Public Sub Login()
...
UserForm1.Show
driver.findElementByName("PASSWORD").SendKeys pass
...
End Sub
这个想法是用户在输入框中输入的任何密码都将分配给变量pass。但是，我遇到的麻烦是将 pass 从 UserForm1 传递到 Module1 的登录子。
我想在我卸载它之前在我的表单中添加类似Module1.Login (pass) 的东西会起作用，但这似乎没有通过任何东西。任何帮助将非常感激。谢谢。
【问题讨论】：
Siddharth 的回答很好，但依赖于全局范围的变量。有一种更好、对 OOP 更友好的方式。
UserForm 和其他任何模块一样是一个类模块——唯一的区别是它有一个隐藏的VB_PredeclaredId 属性设置为True，这使得 VB 创建一个以类命名的全局范围对象变量——这就是你的方式可以编写UserForm1.Show，而无需创建该类的新实例。
远离这一点，将您的表单视为对象 - 公开 Property Get 成员并抽象出表单的控件 - 调用代码无论如何都不关心 控件：
Option Explicit
Private cancelling As Boolean
Public Property Get UserId() As String
UserId = txtUserId.Text
End Property
Public Property Get Password() As String
Password = txtPassword.Text
End Property
Public Property Get IsCancelled() As Boolean
IsCancelled = cancelling
End Property
Private Sub OkButton_Click()
Me.Hide
End Sub
Private Sub CancelButton_Click()
cancelling = True
Me.Hide
End Sub
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = VbQueryClose.vbFormControlMenu Then
cancelling = True
Cancel = True
Me.Hide
End If
End Sub
现在调用代码可以做到这一点（假设用户窗体被命名为LoginPrompt）：
With New LoginPrompt
.Show vbModal
If .IsCancelled Then Exit Sub
DoSomething .UserId, .Password
End With
DoSomething 是一些需要两个字符串参数的过程：
Private Sub DoSomething(ByVal uid As String, ByVal pwd As String)
'work with the parameter values, regardless of where they came from
End Sub
【讨论】：
WithEvents ）。有点像'Apply' logic for UserForm dialog
Me.Hide，我从来没有遇到过任何问题（尽管这有点简化，我实际上将状态标志切换+表单隐藏在我调用的私有OnCancel方法中来自QueryClose 和一些CancelButton_Click 处理程序；链接问题中的代码似乎缺少表单的隐藏，缺少Cancel = True 是导致错误的原因，因为不取消这会使表单对象自我破坏。我正在解决这个问题，谢谢！
不要在用户表单中声明变量。在模块中声明为Public。
Public pass As String
在用户表单中
Private Sub CommandButton1_Click()
pass = UserForm1.TextBox1
Unload UserForm1
End Sub
在模块中
Public pass As String
Public Sub Login()
'
'~~> Rest of the code
'
UserForm1.Show
driver.findElementByName("PASSWORD").SendKeys pass
'
'~~> Rest of the code
'
End Sub
您可能还想在调用driver.find... 行之前添加额外的检查？
If Len(Trim(pass)) <> 0 Then
这将确保不会传递空字符串。
【讨论】：