如何在 Dataweave 2.0 中检查数组中的任何值是否不为空？

Question

我正在将我的有效负载映射到一个新的有效负载，并在输出如下所示的位置添加一个错误数组。 ：

payload : [{

"test: "test",

 "test2" : "",

 "test3" : "test3"

},
{

"test: "test",

 "test2" : "test2",

 "test3" : "test3"

}]

预期输出：`有效载荷：[{

"test: "test",

 "test2" : "",

 "test3" : "test3",

 "Errors" : {

  "test2" : "Test2 is NULL"

  }

},
{

"test: "test",

 "test2" : "test2",

 "test3" : "test3",

 "Errors" : {

  }

}]`

预期输出：我想获得一个输出，其中我只从 Payload 中获取所有对象，其中 Errors 数组具有任何非空值的键，否则应将其过滤掉。

我正在使用下面的表达式来实现，但这不可行，因为它需要我为 Errors 数组中的每个键添加一个空检查。

errArr."Errors" filter ((item, index) -> item."test" != "" or item."test2" != "" or

item."test3" != "")

必须有更好的方法来做到这一点？有没有办法只检查每个项目（键）的值而不定义它们的名称？

Answer 1

试试这个，代码后面有解释：

%dw 2.0
output application/json

var data = [{
    "test": "test",
     "test2" : "",
     "test3" : "test3"
    },
    {
    "test": "test",
     "test2" : "test2",
     "test3" : "test3"
    
    }
]

---
data map {
    ($),
    errors: $ mapObject (v,k) -> (
        if (isEmpty(v)) {(k): "$(k) is empty"} else {}
    )
}

这是算法以及文档中的链接：

1. 使用map 遍历数组中的对象
2. 创建一个新对象并在新对象中添加现有的（键、值）对 使用dynamic elements 功能。
3. 将errors 字段添加到新对象。使用标识所有空字段的mapObject 函数计算errors 对象（注意我说的是空字段，而不仅仅是null）。

我对您的建议是确保您在提问时提供适当范围的输入和输出样本数据集。这将确保您能够更及时地获得问题的答案。

Answer 2

请注意，您的输入中有一些错误。

脚本：

%dw 2.0
import * from dw::core::Arrays
import * from dw::core::Objects
output application/json
---
payload map {
    ($),
    Errors: $ 
                filterObject ((value, key) ->  isEmpty(value)) 
                mapObject ((value, key) ->  (key): key ++ " is NULL") 
}

输入：

[
    {
        "test": "test",
        "test2" : "",
        "test3" : "test3"
    },
    {
        "test": "test",
        "test2" : "test2",
        "test3" : "test3"
    }
]

输出：

[
  {
    "test": "test",
    "test2": "",
    "test3": "test3",
    "Errors": {
      "test2": "test2 is NULL"
    }
  },
  {
    "test": "test",
    "test2": "test2",
    "test3": "test3",
    "Errors": {
      
    }
  }
]

Answer 3

这就是你所追求的吗？

输入

[{
 "test": "test",
 "test2" : "test2",
 "test3" : "test3",
 "Errors" : {
  "test": null,
  "test2" : "Test2 is NULL",
  "test3" : ""
  }
},
{
 "test": "1231test123",
 "test2" : "123test23232",
 "test3" : "12421test3",
 "Errors" : {
  "test": "",
  "test2" : "",
  "test3" : ""
  }
},
{
 "test": "3asdsadasd",
 "test2" : "123123",
 "test3" : "d323e2d23",
 "Errors" : {
  "test": "123",
  "test2" : "",
  "test3" : ""
  }
}
]

脚本

%dw 2.0
import * from dw::core::Arrays
import * from dw::core::Objects
output application/json
---
payload -- (payload map $ filter ( valuesOf( $.Errors ) some ( !isEmpty($) and ($ != null) and sizeOf($) >0)))

输出

[
  {
    "test": "1231test123",
    "test2": "123test23232",
    "test3": "12421test3",
    "Errors": {
      "test": "",
      "test2": "",
      "test3": ""
    }
  }
]