XSLT 映射以删除内部具有 PIPE 分隔符号的双引号答案

【问题标题】：XSLT mapping to remove double quotes which has PIPE delimited symbol insideXSLT 映射以删除内部具有 PIPE 分隔符号的双引号
【发布时间】：2021-11-30 04:49:12
【问题描述】：

专家，我需要编写 XSLT 1.0 代码来消除双引号内的管道分隔符号，还需要删除那些双引号..

输入：

<?xml version="1.0" encoding="utf-8"?>
<ns:MT_FILE>
    <LN>
        <LD>EXTRACT|"28|53"|1308026.7500|1176</LD>
    </LN>
    <LN>
        <LD>DETAIL|1176|"LOS LE|OS PARRILLA"|Y|R||||<LD>
    </LN>
    
</ns:MT_FILE>

** 所需输出：**

<?xml version="1.0" encoding="utf-8"?>
<ns:MT_FILE>
    <LN>
        <LD>EXTRACT|2853|1308026.7500|1176</LD>
    </LN>
    <LN>
        <LD>DETAIL|1176|LOS LE OS PARRILLA|Y|R||||<LD>
    </LN>
    
</ns:MT_FILE>

** 我使用的 XSLT 如下：**

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*/text()">
        <xsl:value-of select="translate(., '\&quot;', '')"/>
    </xsl:template>

</xsl:stylesheet>

此 XSLT 从我的输入字段中删除所有双引号，请在此处提供帮助..

【问题讨论】：

提供格式良好的 XML 作为输入示例有那么难吗？！

标签： xslt xslt-1.0 xslt-grouping exslt

【解决方案1】：

如果可以假设引号总是成对出现，您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="text()">
    <xsl:call-template name="process">
        <xsl:with-param name="text" select="."/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="process">
    <xsl:param name="text"/>
    <xsl:choose>
        <xsl:when test="contains($text, '&quot;')">
            <xsl:value-of select="substring-before($text, '&quot;')"/>
            <xsl:value-of select="translate(substring-before(substring-after($text, '&quot;'), '&quot;'), '|', '')"/>
            <xsl:call-template name="process">
                <xsl:with-param name="text" select="substring-after(substring-after($text, '&quot;'), '&quot;')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

【讨论】：

感谢代码，我还需要从输入字段中删除双引号，到目前为止，我们只考虑使用管道分隔符号的双引号。到相同的代码我如何附加代码以从字符串中删除双引号。
请在您的新问题中发布一个新问题。
stackoverflow.com/questions/69677816/… 我在这里发帖。

【解决方案2】：

当您标记为 EXSLT 时：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:regexp="http://exslt.org/regular-expressions"
  exclude-result-prefixes="regexp">


    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="LD/text()">
        <xsl:value-of select="regexp:replace(., '(&quot;)([^|]+)\|([^&quot;]+)(&quot;)', 'g', '$2$3')"/>
    </xsl:template>
    
</xsl:stylesheet>

【讨论】：