XSL 从另一个文档评估动态 XPATH

Question

我在下面定义了两个示例文档。在 module_meta.xml 中，只有 xpath /mdata/effectivity 上的效果节点是相关的。如下所示，它们包含一个path 属性和一个effrg 属性。现在的目标是评估module.xml 上的xpath（在module_meta.xml 中定义为path 属性）并将effrg 附加到它上面。有关所需结果，请参阅desired_output.xml。 xsl 转换应用于module.xml。我知道我必须使用document() 函数来“包含”module_meta.xml，但到目前为止我很茫然。

module.xml

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE proc>
    
<procbody>
 <info>
  <action lid="a">
  </action>
  <action lid="b">
  </action>
  <action lid="c">
  </action>
 </info>
</procbody>

module_meta.xml

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE mdata>
<mdata>
  <metadata>
    <metadata-item name="n1" value="v1" />
    <metadata-item name="n2" value="v2" />
    <metadata-item name="n3" value="v3" />
  </metadata>
  <effectivity>
    <effect path="//*[@lid='a']" effrg="0074 0080 0087" />
    <effect path="//*[@lid='b']" effrg="0136 0146 0174" />
  </effectivity>
</mdata>

desired_output.xml

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE proc>
        
<procbody>
 <info>
  <action lid="a" effrg="0074 0080 0087">
  </action>
  <action lid="b" effrg="0136 0146 0174">
  </action>
  <action lid="c">
  </action>
 </info>
</procbody>

Answer 1

在支持 xsl:evaluate 的 XSLT 3 中：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  xmlns:mf="http://example.com/mf"
  expand-text="yes">
  
  <xsl:function name="mf:evaluate" as="element(action)?">
    <xsl:param name="effect" as="element(effect)"/>
    <xsl:evaluate xpath="$effect/@path" context-item="$main-doc"/>
  </xsl:function>

  <xsl:variable name="main-doc" select="/"/>
  
  <xsl:mode on-no-match="shallow-copy"/>
  
  <xsl:template match="info/action">
    <xsl:copy>
      <xsl:apply-templates select="@*, $meta//effect[current() is mf:evaluate(.)]/@effrg"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:param name="meta">
<mdata>
  <metadata>
    <metadata-item name="n1" value="v1" />
    <metadata-item name="n2" value="v2" />
    <metadata-item name="n3" value="v3" />
  </metadata>
  <effectivity>
    <effect path="//*[@lid='a']" effrg="0074 0080 0087" />
    <effect path="//*[@lid='b']" effrg="0136 0146 0174" />
  </effectivity>
</mdata>
  </xsl:param>
  
</xsl:stylesheet>

为了示例的自包含性，第二个文档是作为参数内联的，但您当然可以改用<xsl:param name="meta" select="doc('module_meta.xml')"/>。

对于每个effect 元素只使用一次xsl:evaluate 可能会更有效，例如，通过声明一个这样做的键，并存储生成的ID（如果有）：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  xmlns:mf="http://example.com/mf"
  expand-text="yes">
  
  <xsl:key name="ref" match="mdata/effectivity/effect">
    <xsl:variable name="referenced-node" as="node()?">
      <xsl:evaluate xpath="@path" context-item="$main-doc" as="node()?"/>
    </xsl:variable>
    <xsl:sequence select="generate-id($referenced-node)"/>
  </xsl:key>

  <xsl:variable name="main-doc" select="/"/>
  
  <xsl:mode on-no-match="shallow-copy"/>
  
  <xsl:template match="info/action">
    <xsl:copy>
      <xsl:apply-templates select="@*, key('ref', generate-id(), $meta)/@effrg"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:param name="meta">
<mdata>
  <metadata>
    <metadata-item name="n1" value="v1" />
    <metadata-item name="n2" value="v2" />
    <metadata-item name="n3" value="v3" />
  </metadata>
  <effectivity>
    <effect path="//*[@lid='a']" effrg="0074 0080 0087" />
    <effect path="//*[@lid='b']" effrg="0136 0146 0174" />
  </effectivity>
</mdata>
  </xsl:param>
  
</xsl:stylesheet>

如果您想匹配其他文档中引用的任何元素并复制除path 之外的任何属性，您可以将具有match="info/action" 的模板更改为

  <xsl:template match="*[key('ref', generate-id(), $meta)]">
    <xsl:copy>
      <xsl:apply-templates select="@*, key('ref', generate-id(), $meta)/(@* except @path), node()"/>
    </xsl:copy>
  </xsl:template>