根据长度和逗号拆分输入字符串（送货地址数据）

Question

我需要帮助，请根据它的字符长度以及它是否在单词中间以及是否有任何逗号来拆分 XML 中的源数据。 EG：我的收货地址行的长度不能超过 35 个字符（这包括任何空格、逗号等，理想情况下我想拆分地址以确保我想输出的 2 个地址行不超过 35 个字符，如果我根据这个最大限制拆分源数据，我要么在逗号处执行，要么在单词末尾执行，然后将剩余数据附加到下一行，等等开，以免丢失客户提供的任何数据（在可避免的情况下）。

我目前正在使用 XSLT 版本 1，但如果需要，可以支持使用版本 2。

这是我的源数据，我一直在尝试做什么以及我想要的输出是什么。仅供参考，我的输出采用管道分隔格式。

XML

<AddressData> 
   <Delivery> 
      <ConsigneeAddress>Rosedal 67, departamento 3A, Lomasde Chapultepec, Miguel hidalgo</ConsigneeAddress> 
      <ConsigneeAddress2/> 
   </Delivery> 
   <Delivery> 
      <ConsigneeAddress>Str.Codreanu,30, Chisinau, MD-200018,</ConsigneeAddress> 
      <ConsigneeAddress2>Moldova, Republic of</ConsigneeAddress2> 
   </Delivery> 
</AddressData>

XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
<xsl:output method="text" version="1.0" encoding="UTF-8" indent="yes"/>  

<xsl:template match="/">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="/">    
    <xsl:for-each select="/AddressData/Delivery">
        <xsl:choose>
                <xsl:when test="string-length(./ConsigneeAddress) &#62; 35">
                        <xsl:value-of select="substring-before(./ConsigneeAddress,',')"/><xsl:text>, </xsl:text><xsl:value-of select="substring-before(substring-after(./ConsigneeAddress,','),',')"/>
                            <xsl:if test="./ConsigneeAddress2=''">
                                <xsl:text>|</xsl:text>
                                <xsl:value-of select="normalize-space(substring-before(substring-after(substring-after(./ConsigneeAddress,','),','),./ConsigneeZipCode))"/>
                            </xsl:if>
                            <xsl:if test="./ConsigneeAddress2!=''">
                                <xsl:text>|</xsl:text>
                                <xsl:value-of select="normalize-space(./ConsigneeAddress2)"/><xsl:text>, </xsl:text><xsl:value-of select="normalize-space(substring-after(substring-after(./ConsigneeAddress,','),','))"/>
                                </xsl:if>
                        </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="./ConsigneeAddress"/>
                    <xsl:text>|</xsl:text>
                    <xsl:value-of select="./ConsigneeAddress2"/>
                </xsl:otherwise>
            </xsl:choose>
    </xsl:for-each> 
</xsl:template>
</xsl:stylesheet>

期望的输出：

Rosedal 67，departamento 3A|Lomasde Chapultepec，米格尔伊达尔戈
Str.Codreanu,30, 基希讷乌,|MD-200018, 摩尔多瓦, 共和国

任何帮助/帮助将不胜感激。提前谢谢你。

Answer 1

您可以更改为 XSLT 2 很好，因为 tt 具有更强大的功能。 其中一个对您有用的是analyze-string。

您可以使用以下脚本：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="text" />

  <xsl:template match="/">
    <xsl:for-each select="/AddressData/Delivery">
      <xsl:apply-templates select="ConsigneeAddress"/>
      <xsl:if test="position() &lt; last()">
        <xsl:text>&#10;</xsl:text>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="ConsigneeAddress">
    <xsl:analyze-string select="."
      regex="(\w.{{0,33}}\w)(,\s*|$)">
      <xsl:matching-substring>
        <xsl:value-of select="regex-group(1)"/>
        <xsl:if test="position() &lt; last()">
          <xsl:text>|</xsl:text>
        </xsl:if>
      </xsl:matching-substring>
    </xsl:analyze-string>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy><xsl:apply-templates select="@*|node()"/></xsl:copy>
  </xsl:template>
</xsl:transform>

关于使用的正则表达式的解释：

要匹配的每个子字符串：

• 应以单词字符 (\w) 开头。
• 那么它应该包含最多 33 个任意字符。 请注意，“普通”正则表达式将具有 single { 和 } 但在这里（由于 XSLT 语法）它们必须加倍。
• 要捕获的最后一个字符又是一个单词字符。

以上所有项目（总共最多 35 个字符）构成第一个捕获组。

之后还有另一个包含 2 个变体的组：

• 逗号和“白色”字符序列，
• 或字符串的结尾。

他们也应该在这里“消费”，以便开始下一次搜索 在他们之后。

从这两组中，我们实际上只对第一组感兴趣， 所以在 XSLT 脚本 value-of 语句中只打印出这个 第一组 (regex-group(1))。

捕获的组打印出来后，脚本打印出|， 但只是“在序列的中间”（即不是在最后一个之后 匹配的字符串）。

主模板还在每个ConsigneeAddress之后打印一个换行符 但最后一个。