唯一排序节点之前的 XSL 计数

Question

我有一个相当复杂的 XSL 任务。我有一个类似的 XML 文档

<authorlist>
    <orgs>
        <org id="org1" name="Org A"/>
        <org id="org2" name="Org B"/>
        <org id="org3" name="Org C"/>
    </orgs>
    <authors>
        <auth name="C. Thor">
            <affiliations>
                <affil id="org2"/>
                <affil id="org3"/>
            </affiliations>
        </auth>
        <auth name="A. Thor">
            <affiliations>
                <affil id="org3"/>
            </affiliations>
        </auth>
        <auth name="B. Thor">
            <affiliations>
                <affil id="org1"/>
            </affiliations>
        </auth>
    </authors>
</authorlist>

我想编写一个 XSL 转换，它将产生以下（文本）输出

1 Org C
2 Org A
3 Org B

A. Thor ^{1}
B. Thor ^{2}
C. Thor ^{1,3}

也就是说，作者按姓名字母顺序排序。每个作者的名字都被打印出来，以及表明她的隶属关系的上标。组织按照它们在作者排序列表中首次出现的顺序打印。每个作者可能有多个隶属关系。

这是我认为我需要做的：

1. 创建一个从组织映射到序数的键，以便我可以正确地对组织进行排序（并将正确的上标放在作者姓名上）。我相信我知道该怎么做。
2. 要创建该密钥，我需要计算与当前（创建密钥时）组织有关联的作者的第一个实例之前的唯一作者隶属关系的数量。我想我知道该怎么做。
3. 关键是如何定义“在前”和“在前”。如果我理解正确，“preceding”和“first”是由文档顺序定义的，或者可能是由一些模糊的 XPath“处理顺序”定义的。我非常需要通过按作者姓名字母顺序对作者进行排序来定义“在先”和“第一”。我不知道如何做到这一点，甚至不知道这是否可能。

我可以使用的 XSLT 处理器是 xsltproc，它实现了 XSLT 1.0。如果有足够令人信服的案例，我可以考虑提供不同的处理器，但我能否使用不同的处理器有点怀疑。

现实世界的情况会变得更加复杂，因为有些组织有多个子组织，而且还有两类组织，成员组织和访客组织，它们打印在单独的列表中，并且具有独立的顺序他们的上标。但是，我认为解决上述问题就足够了。

Answer 1

一种方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" />

  <xsl:variable name="orgIndex">
    <xsl:apply-templates select="//authors/auth" mode="orgIdx">
      <xsl:sort select="@name" />
    </xsl:apply-templates>
  </xsl:variable>

  <xsl:template match="authorlist">
    <xsl:apply-templates select="authors" />
  </xsl:template>

  <xsl:template match="authors">
    <xsl:apply-templates select="auth">
      <xsl:sort select="@name" />
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="auth">
    <xsl:value-of select="@name" />
    <xsl:text> ^{</xsl:text>
    <xsl:apply-templates select="affiliations/affil" mode="orgIdx">
      <xsl:sort select="string-length(substring-before($orgIndex, @id))" data-type="number" />
    </xsl:apply-templates>
    <xsl:text>}</xsl:text>
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="'&#xA;'" />
    </xsl:if>
  </xsl:template>

  <xsl:template match="affil" mode="orgIdx">
    <xsl:variable name="str" select="substring-before($orgIndex, @id)" />
    <xsl:variable name="idx" select="string-length($str) - string-length(translate($str, '|', ''))" />
    <xsl:value-of select="$idx" />
    <xsl:if test="position() &lt; last()">,</xsl:if>
  </xsl:template>

  <xsl:template match="auth" mode="orgIdx">
    <xsl:for-each select="affiliations/affil">
      <xsl:value-of select="concat('|', @id)" /> 
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

结果

A. 雷神 ^{1} B. 雷神 ^{2} C. 雷神 ^{1,3}

此方法基于以正确的顺序（即按名称字母顺序按auth，按文档顺序在auth 内）构建一个分隔字符串affil/@id。

对于您的示例，字符串 $orgIndex 将是 '|org3|org1|org2|org3'。

@ids 将在该字符串中重复，但这没关系，因为我们不关心字符串的后部。

现在我们可以使用substring-before() 来确定第一次出现 ID 之前的分隔字符数，这会导致您似乎正在寻找数字索引。