使用 XSLT 将 XML 元素转换为 XML 属性

Question

我们有一个当前系统可以输出以下格式的 XML 文件：

<INVENTORY>
   <ITEM>
      <SERIALNUMBER>something</SERIALNUMBER>
      <LOCATION>something</LOCATION>
      <BARCODE>something</BARCODE>
   </ITEM>
</INVENTORY>

我需要使用这些数据加载到标准的 .NET 2.0 网格中。但是网格需要 XML 格式如下：

<INVENTORY>
   <ITEM serialNumber="something" location="something" barcode="something">
   </ITEM>
</INVENTORY>

即item的子节点需要转化为item节点的属性。

有人知道如何使用 XSLT 做到这一点吗？

Answer 1

应该这样做：

  <xsl:for-each select="//ITEM">
    <xsl:element name="ITEM">
      <xsl:attribute name="serialNumber">
        <xsl:value-of select="SERIALNUMBER"/>
      </xsl:attribute>
      <xsl:attribute name="location">
        <xsl:value-of select="LOCATION"/>
      </xsl:attribute>
      <xsl:attribute name="barcode">
        <xsl:value-of select="BARCODE"/>
      </xsl:attribute>
    </xsl:element>
  </xsl:for-each>

或者使用大卫的快捷方式：

<xsl:for-each select="//ITEM">
  <ITEM serialNumber="{SERIALNUMBER}" location="{LOCATION}" barcode="{BARCODE}"/>
</xsl:for-each>

Answer 2

如果您的来源如下所示：

<row><a>1</a><b>2</b></row>

你希望它看起来像这样：

<row a="1" b="2" />

那么这个 XSLT 应该可以工作了：

<xsl:template match="row">
    <row a="{a}" b="{b}" />
</xsl:template>

Answer 3

这两个模板应该可以做到：-

<xsl:template match="ITEM">
   <ITEM serialNumber="{SERIALNUMBER}" location="{LOCATION}" barcode="{BARCODE}" />
</xsl:template>

<xsl:template match="INVENTORY">
   <INVENTORY>
      <xsl:apply-templates />
   </INVENTORY>
</xsl:template>

Answer 4

这应该可行：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="INVENTORY">
    <INVENTORY>
      <xsl:apply-templates/>
    </INVENTORY>
  </xsl:template>

  <xsl:template match="ITEM">
    <ITEM>
      <xsl:for-each select="*">
        <xsl:attribute name="{name()}">
          <xsl:value-of select="text()"/>
        </xsl:attribute>

      </xsl:for-each>
    </ITEM>
  </xsl:template>
</xsl:stylesheet>

Answer 5

这可能是最简单的解决方案，它将ITEM 的任何子元素转换为其属性，并按原样复制其他所有内容，同时将元素名称转换为任何所需的属性名称：

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
<!--                                              --> 
  <xsl:strip-space elements="*"/>

  <xsl:variable name="vrtfNameMapping">
    <item name="SERIALNUMBER" newName="serialNumber"/>
    <item name="LOCATION" newName="location"/>
    <item name="BARCODE" newName="barcode"/>
  </xsl:variable>
 <!--                                              --> 
  <xsl:variable name="vNameMapping" select=
  "document('')/*/xsl:variable[@name='vrtfNameMapping']"/>
<!--                                              --> 

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
<!--                                              --> 
  <xsl:template match="ITEM/*">
    <xsl:attribute name=
     "{$vNameMapping/*[@name=name(current())]/@newName}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

当上述转换应用于提供的 XML 文档时：

<INVENTORY>
    <ITEM>
        <SERIALNUMBER>something</SERIALNUMBER>
        <LOCATION>something</LOCATION>
        <BARCODE>something</BARCODE>
    </ITEM>
</INVENTORY>

产生想要的结果：

<INVENTORY>
   <ITEM serialNumber="something" location="something" barcode="something"/>
</INVENTORY>

请注意以下几点：

1. identity rule的使用

2. <xsl:strip-space elements="*"/>的使用

3. 变量vrtfNameMapping的使用没有任何xxx:node-set()扩展函数。

4. 事实上，我们处理名称和 newName 之间的任何映射，而不仅仅是简单的小写。