每个处理程序阅读器的 Scotty monad 转换器

Question

在问题Web, Scotty: connection pool as monad reader 中，展示了如何使用ScottyT 在堆栈中嵌入Reader monad 以访问静态配置（在这种情况下为连接池）。

我有一个类似的问题，但更简单——或者至少我是这么认为的……

我想将Reader 添加到单个处理程序（即ActionT），而不是整个应用程序。

我从上面的问题开始修改程序，但我不知道如何将ActionT Text (ReaderT String IO) 转换为处理程序需要的ActionT Text IO。在摸索并尝试使用打字孔希望了解如何构建它之后，我现在不得不放弃并寻求帮助。我真的觉得这应该很简单，但不知道该怎么做。

这是程序，我卡住的行突出显示：

{-# LANGUAGE OverloadedStrings #-}

import qualified Data.Text.Lazy as T
import           Data.Text.Lazy (Text)
import           Control.Monad.Reader
import           Web.Scotty.Trans

type ActionD = ActionT Text (ReaderT String IO)

main :: IO ()
main = do
  scottyT 3000 id id app

-- Application
app ::  ScottyT Text IO ()
app = do
  get "/foo" $ do
    h <- handler              -- ?
    runReaderT h "foo"        -- ?
--get "/bar" $ do
--  h <- handler
--  runReaderT h "bar"

-- Route action handler
handler ::  ActionD ()
handler = do
  config <- lift ask
  html $ T.pack $ show config

Answer 1

如果您想在单独的阅读器中运行每个操作，则根本不需要更复杂的Scotty.Trans 接口。您可以反过来构建您的 monad 堆栈，在顶部使用 ReaderT。

import qualified Data.Text.Lazy as T
import           Control.Monad.Reader
import           Web.Scotty

type ActionD = ReaderT String ActionM

main :: IO ()
main = do
  scotty 3000 app

-- Application
app ::  ScottyM ()
app = do
  get "/foo" $ do
    runReaderT handler "foo"

-- Route action handler
handler ::  ActionD ()
handler = do
  config <- ask
  lift $ html $ T.pack $ show config