如何通过 netConnection 和 netStream 播放 RTMP 视频答案

【问题标题】：How can I play a RTMP video through netConnection and netStream如何通过 netConnection 和 netStream 播放 RTMP 视频
【发布时间】：2013-04-04 18:06:15
【问题描述】：

我正在开发一个原型，我必须在其中通过 RTMP 协议播放视频。我的代码如下：

private function init():void
    {
        streamID:String = "mp4:myVideo";
        videoURL = "rtmp://fms.xstream.dk/*********.mp4";
        vid = new video();
        vid.width = 480;
        vid.height = 320;

        nc = new NetConnection();
        nc.client = {onBWDone: function():void
            {
            }};
        nc.addEventListener(NetStatusEvent.NET_STATUS, onConnectionStatus);
        nc.connect(videoURL);           
    }

    private function onConnectionStatus(e:NetStatusEvent):void
    {
        if (e.info.code == "NetConnection.Connect.Success")
        {
            trace("Creating NetStream");
            netStreamObj = new NetStream(nc);
            netStreamObj.client = new CustomClient();
            netStreamObj.play(streamID);
            vid.attachNetStream(netStreamObj);
            addChild(vid);
            intervalID = setInterval(playback, 1000);
        }
    }

    private function playback():void
    {
        trace((++counter) + " Buffer length: " + netStreamObj.bufferLength);
    }





class CustomClient 
{
public function onMetaData(info:Object):void
{
    trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
}
public function onCuePoint(info:Object):void
{
    trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
}

}

但它没有播放，没有发生任何错误，也没有运行，如果有人有任何想法，请帮助我。

【问题讨论】：

我会在调用nc.connect之前添加事件处理程序nc.addEventListener，并在onConnectionStatus中添加一些跟踪。
我将 nc.addEventListener 放在 nc.connect 之上，但仍然没有任何反应，并且有一个跟踪跟踪（“Creating NetStream”），我在输出中得到了那个跟踪。
很高兴您正在获得正在创建的网络流，但这不是您可以获得的唯一消息，请跟踪 e.info.code 作为处理程序中的第一行。
我将 trace(e.info.code) 放在第一行，它会跟踪“NetConnection.Connect.Success”。但仍然没有发生任何事情。
类似问题：stackoverflow.com/questions/8971272/…

标签： actionscript-3 flash rtmp flash-player-11

【解决方案1】：

这样做对我有用。我只是以新闻频道的链接为例，因此请尝试将其替换为您自己的流 url。（ps：忽略像素化，这是一个低分辨率的示例链接）。

另外..首先你有一个错字，你说vid = new video();（意思是= new Video??）。这可能是addChild(vid) 进一步的问题吗？其次，您需要像我在使用 RTMP 时包含的 asyncErrorHandler、onFCSubscribe 和 onBWDone 之类的函数来阻止某些流抛出的错误（无论如何，在我过去的经历中）。此示例代码位于名为 RTMP_test.as 的文档类中（重命名为首选）...

package  {

import flash.display.*; 
import flash.events.*;
import flash.net.*;
import flash.media.*;
import flash.system.*;
import flash.utils.ByteArray;

public class RTMP_test extends MovieClip 
{
    public var netStreamObj:NetStream;
    public var nc:NetConnection;
    public var vid:Video;

    public var streamID:String;
    public var videoURL:String;
    public var metaListener:Object;

public function RTMP_test () 
{ init_RTMP(); }

function init_RTMP():void
{
        /*
        streamID  = "mp4:myVideo";
        videoURL = "rtmp://fms.xstream.dk/*********.mp4";
        */
        streamID  = "QVCLive1@14308";
        videoURL = "rtmp://cp79650.live.edgefcs.net/live/";

        vid = new Video(); //typo! was "vid = new video();"

        nc = new NetConnection();
        nc.addEventListener(NetStatusEvent.NET_STATUS, onConnectionStatus);
        nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
        nc.client = { onBWDone: function():void{} };
        nc.connect(videoURL);           
}

private function onConnectionStatus(e:NetStatusEvent):void
{
        if (e.info.code == "NetConnection.Connect.Success")
        {
            trace("Creating NetStream");
            netStreamObj = new NetStream(nc);

            metaListener = new Object();
            metaListener.onMetaData = received_Meta;
            netStreamObj.client = metaListener;

            netStreamObj.play(streamID);
            vid.attachNetStream(netStreamObj);
            addChild(vid);
            //intervalID = setInterval(playback, 1000);
        }
}

private function playback():void
{ 
  //trace((++counter) + " Buffer length: " + netStreamObj.bufferLength); 
}

public function asyncErrorHandler(event:AsyncErrorEvent):void 
{ trace("asyncErrorHandler.." + "\r"); }

public function onFCSubscribe(info:Object):void
{ trace("onFCSubscribe - succesful"); }

public function onBWDone(...rest):void
{ 
    var p_bw:Number; 
    if (rest.length > 0)
      { p_bw = rest[0]; }
    trace("bandwidth = " + p_bw + " Kbps."); 
}

function received_Meta (data:Object):void
{
    var _stageW:int = stage.stageWidth;
    var _stageH:int = stage.stageHeight;

    var _videoW:int;
    var _videoH:int;
    var _aspectH:int; 

    var Aspect_num:Number; //should be an "int" but that gives blank picture with sound
    Aspect_num = data.width / data.height;

    //Aspect ratio calculated here..
    _videoW = _stageW;
    _videoH = _videoW / Aspect_num;
    _aspectH = (_stageH - _videoH) / 2;

    vid.x = 0;
    vid.y = _aspectH;
    vid.width = _videoW;
    vid.height = _videoH;
}

    } //end class

} //end package

更新代码：

新的演示链接：现在是 QVC（英国购物）而不是今日俄罗斯（世界新闻）。
已添加行：nc.client = { onBWDone: function():void{} };（因为 Flash Player 现在更加严格。之前没有此行也可以正常工作）。

【讨论】：

谢谢 VC.one，它正在工作。但是当我输入我的 RTMP URL 时，它不起作用，似乎我的 URL 有问题，无论如何非常感谢。
很难说你自己的 url 有什么问题，但这条线 streamID = "mp4:myVideo"; 听起来它不能连接到流。像这样试试streamID = "myVideo"; 或者甚至试试这个.. streamID = "*********.mp4"; videoURL = "rtmp://fms.xstream.dk/"; 除此之外，我不能在没有看到完整网址的情况下提出建议。此外，如果这只是一些“在网上找到”链接，那么可以以某种方式保护流。例如：他们自己的播放器在公共可见链接中调整某些内容以获得实际流。既然你说这是一个演示原型，也许任何其他链接都足以作为你概念的一部分展示？？
谢谢 VC.One，它现在正在运行，但我还有另一个问题，我想在我的设备 (iPad2) 上播放它，但是当我创建它的 IPA 文件并将其安装在ipad，它显示空白屏幕，你知道它可以在IOS上播放MP4视频吗？如果不是，那是什么？？
不幸的是我不使用IOS，所以我对技术问题没有任何线索。也许它不喜欢 MP4 文件？在您的 IPA 文件中尝试我的链接我认为它是 .FLV 格式。另一种方法是搜索 Stack Overflow..
如何使用 adobe air 在 android 中实现它？

【解决方案2】：

也许更完整的代码版本是这样的。它应该实时播放 RT 频道。

package  {
import flash.events.NetStatusEvent;
import flash.events.AsyncErrorEvent;
import flash.display.MovieClip;
import flash.net.NetStream;
import flash.net.NetConnection;
import flash.media.Video;
import flash.utils.setInterval;


public class RTMP_test extends MovieClip {


    public var netStreamObj:NetStream;
    public var nc:NetConnection;
    public var vid:Video;

    public var streamID:String;
    public var videoURL:String;
    public var metaListener:Object;

    public var intervalID:uint;
    public var counter:int;

    public function RTMP_test ()
    { init_RTMP(); }

    function init_RTMP():void
    {

            streamID  = "RT_2";
            videoURL = "rtmp://fms5.visionip.tv/live/RT_2";


            vid = new Video(); //typo! was "vid = new video();"

            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onConnectionStatus);
            nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            nc.connect(videoURL);          
    }

    private function onConnectionStatus(e:NetStatusEvent):void
    {
            if (e.info.code == "NetConnection.Connect.Success")
            {
                trace("Creating NetStream");
                netStreamObj = new NetStream(nc);

                metaListener = new Object();
                metaListener.onMetaData = received_Meta;
                netStreamObj.client = metaListener;

                netStreamObj.play(streamID);
                vid.attachNetStream(netStreamObj);
                addChild(vid);
                intervalID = setInterval(playback, 1000);
            }
    }

    private function playback():void
    {
      trace((++counter) + " Buffer length: " + netStreamObj.bufferLength);
    }

    public function asyncErrorHandler(event:AsyncErrorEvent):void
    { trace("asyncErrorHandler.." + "\r"); }

    public function onFCSubscribe(info:Object):void
    { trace("onFCSubscribe - succesful"); }

    public function onBWDone(...rest):void
    {
        var p_bw:Number;
        if (rest.length > 0)
          { p_bw = rest[0]; }
        trace("bandwidth = " + p_bw + " Kbps.");
    }

    function received_Meta (data:Object):void
    {
        var _stageW:int = stage.stageWidth;
        var _stageH:int = stage.stageHeight;
        var _aspectH:int;
        var _videoW:int;
        var _videoH:int;

        var relationship:Number;
        relationship = data.height / data.width;

        //Aspect ratio calculated here..
        _videoW = _stageW;
        _videoH = _videoW * relationship;
        _aspectH = (_stageH - _videoH) / 2;

        vid.x = 0;
        vid.y = _aspectH;
        vid.width = _videoW;
        vid.height = _videoH;
    }

}

}

【讨论】：