通过批处理导入当前目录中的所有 schtasks .xml 文件

Question

我知道可以像这样导入多个任务：

schtasks.exe /create /TN "Task 1 Name" /XML "Full_Path_of_Backup_XML_File"
schtasks.exe /create /TN "Task 2 Name" /XML "Full_Path_of_Backup_XML_File"
schtasks.exe /create /TN "Task 3 Name" /XML "Full_Path_of_Backup_XML_File"

但我更喜欢一种更动态的方式来导入当前目录中的所有 schtasks .xml 文件。很像 this 这里的批处理（.xml 而不是 .reg）：

rem @echo off
cls
SET folder=%~dp0
for %%i in ("%folder%*.reg") do (regedit /s "%%i")
echo done
pause
EXIT

有人可以指导我正确的方向吗？ :)

Answer 1

您的意思是要遍历与批处理文件脚本位于同一目录中的每个 XML 文件吗？然后用找到的每个 XML 文件创建一个计划任务？如果是这种情况，您可以尝试这样的事情（假设 XML 文件可用于创建计划任务）：

@echo off

setlocal enabledelayedexpansion

for %%e in ("%~dp0*.xml") do (
  set /a "count+=1"
  schtasks /create /tn "Task !count! Name" /xml "%%~e"
)

---

如果您需要能够将包含感叹号的 XML 文件名传递给 schtasks 命令行工具，请改用以下代码：

@echo off

setlocal disabledelayedexpansion
set "count=1"

for %%e in ("%~dp0*.xml") do (
  set "file=%%~e"
  setlocal enabledelayedexpansion
  schtasks /create /tn "Task !count! Name" /xml "!file!"
  endlocal & set /a "count+=1"
)

---

还有一个问题，如何将任务命名为 .xml 文件名？

这实际上会简化事情，因为在执行期间不需要在 for 循环体中扩展单独的变量：

@echo off

setlocal disabledelayedexpansion

for %%e in ("%~dp0*.xml") do (
  schtasks /create /tn "%%~ne" /xml "%%~e"
)