如何在新的 CMD 窗口中获取 CMD 和 Ping 中的 IPV4 变量答案

【问题标题】：How to grab IPV4 variable in CMD and Ping in new CMD window如何在新的 CMD 窗口中获取 CMD 和 Ping 中的 IPV4 变量
【发布时间】：2016-08-08 20:04:21
【问题描述】：

所以这就是想法，我正在尝试从 Cmd 中获取一个变量，例如 IPv4，并能够在新窗口中 ping 它。

通过运行命令并获取该命令的特定部分并能够在新命令行中将其作为新变量输入以便执行操作，逻辑是什么？

另一个例子：

查找计算机名称。
对计算机名称末尾的数字运行命令。

我目前正在下载 Visual Basics 软件，因为它看起来可能是我可能需要但很困惑的语言。

有没有人对我可以使用什么有任何基本的想法或有这个例子？

【问题讨论】：

标签： batch-file cmd batch-processing

【解决方案1】：

你可以试试这样的：

@Echo off
Color 0A & Mode con cols=80 lines=15
Title How to grab IPv4
::**********************************
::Method1
::**********************************
echo( 
echo Method 1 with arp -a
echo( 
For /f "tokens=2 delims= " %%a in ('arp -a ^|findstr /i "Interface"') do (set IP=%%a)
Echo The Local IPv4 adress is : %IP%
pause
Cls
Call:PingHost %IP%
pause
::**********************************
::Method2
::**********************************
cls
echo( 
echo Method 2 with ipconfig
for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do (
  set ip=%%b
)
set ip=%ip:~1%
echo( 
echo The Local IPv4 adress is : %ip%
pause
Cls
Call:PingHost %IP%
pause
::**********************************
::Method3 by Stephan
::**********************************
cls
echo( 
echo Method 3 with %%computername%% = %computername%
for /f "tokens=2 delims=[]" %%i in ('ping -4 -n 1 %computername%') do set ip=%%i
echo( 
echo The Local IPv4 adress is : %ip%
pause
Cls
Call:PingHost %IP%
Pause
exit
::**********************************
:Pinghost
Start "%1" Ping %1
exit /b
::**********************************

【讨论】：

方法 3 与 ping：for /f "tokens=2 delims=[]" %$i in ('ping -4 -n 1 %computername%') do set ip=%%i
@Stephan 感谢 Stephan 提供此方法 3，所以我编辑并在我的答案中添加了您的第三个方法！