CMD Fileless 相当于 < 重定向

Question

我有一批包装 AnyConnect 移动客户端 CLI (vpncli.exe) 并要求用户名和密码稍后将它们处理到 vpncli。

简化代码：

set /p user_id=Username:
set /p pwd=Password:
echo %user_id%> c:\temp\configvpn.txt
echo %pwd%>> c:\temp\configvpn.txt

set install_dir="C:\Program Files (x86)\Cisco\Cisco AnyConnect Secure Mobility Client"

%install_dir%\vpncli.exe connect myvpn.mydomain.TLD -s < c:\temp\configvpn.txt

net use h: \\fileserver\sharename /user:domain\%user_id% %pwd%

最后一行是我们这样做的原因：不提示用户密码两次（第一次用于连接 VPN，第二次用于映射网络驱动器）

出于安全原因，我正在改进脚本以不将密码写入磁盘。 我需要一个无文件等效的“

我试过了：

(
    @echo %user_id%
    @echo %pwd% 
) | %install_dir%\vpncli.exe connect myvpn.mydomain.TLD -s

目前还没有成功。输出是这个循环：

  >> Please enter your username and password.
Group: VPN-TESTGROUP

Username: [myUsername] Password:
  >> Login failed.
Group: VPN-TESTGROUP

Username: [myUsername] Password:
  >> Login failed.

（无限重复）

有没有办法做到这一点？

Answer 1

正如您已经发现的那样，问题在于管道内的尾随空格，正如您在jeb's answer 中看到的那样，要摆脱尾随空格需要特殊处理。

管道导致混淆的一个方面是管道命令不是在批处理文件上下文中使用批处理语法规则执行，而是在命令行上下文中执行，并且在子 cmd 实例中使用命令行语法规则。

需要彻底了解 CMD/Batch 管道的机制，才能以这种方式构建和维护有效的解决方案，对于稍微复杂的管道块来说，这不是一项简单的任务。

这是一种替代方法，它可以像在普通批处理代码中一样灵活地管道任何复杂的命令块。

@echo off
if "%~1"=="/LPipe" goto :/LPipe
if "%~1"=="/RPipe" goto :/RPipe

set /p user_id=Username:
set /p pwd=Password:

"%~f0" /LPipe | "%~f0" /RPipe
exit /b


:/LPipe
REM This will be executed inside a pipe but in batch context

REM Enable delayed expansion to be able to send any special characters
setlocal EnableDelayedExpansion

REM It's easy to take care of trailing spaces, no special hacks needed.
echo !user_id!
echo !pwd!
goto :EOF


:/RPipe
REM This will be executed inside a pipe but in batch context

%install_dir%\vpncli.exe connect myvpn.mydomain.TLD -s
goto :EOF

Answer 2

这可能是管道块的问题，因为每个命令的末尾都添加了空格。

此代码避免了空格，应该可以解决您的问题

(SET LF=^
%=empty=%
)

(
    echo %user_id%%%LF%%rem.
    echo %pwd%%%LF%%rem.
) |  %install_dir%\vpncli.exe connect myvpn.mydomain.TLD -s

但您应该在 user_id 或密码中不包含任何特殊字符的情况下对其进行测试！