如何将找到的单元格变成一个范围？

Question

如果您能提供帮助，我将不胜感激，因为我真的很想让它发挥作用。我这里有一些代码，旨在从电子表格的一部分中提取信息并将其粘贴到电子表格另一部分的表格中。

For i = 1 To 24
        Range("J11:J100").Select
        Set foundCell = Cells.Find(What:="PL " & i, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
            :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
            False, SearchFormat:=False)
        If Not foundCell Is Nothing Then
            foundCell.Activate
            foundCell.Copy
            Range("P" & (i + 10)).Select
            ActiveSheet.Paste
        End If
        Next

主要问题是我还想使用 foundCell 作为参考从周围的列中复制信息，例如。 foundCell.Offset(, -4).Copy

我添加了这个，但它不起作用（附录已标记）：

    For i = 1 To 24
            Range("J11:J100").Select
            Set foundCell = Cells.Find(What:="PL " & i, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
                :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
                False, SearchFormat:=False)
            If Not foundCell Is Nothing Then
                foundCell.Activate
                foundCell.Copy
                Range("P" & (i + 10)).Select
                ActiveSheet.Paste
' BEGIN ADDITION
                foundCell.Offset(, -4).Copy
                Range("S" & (i + 10)).Select
                ActiveSheet.Paste
'END ADDITION
            End If
            Next

我进行了测试，发现 foundCell 现在引用的是数据粘贴到的范围，而不是找到它的原始范围。

谁能帮帮我？我对任何事情都持开放态度。我觉得最好的解决方案是将 foundCell 变成一个范围，但我不知道该怎么做。

Answer 1

以下应该可以解决您的问题：

For i = 1 To 24
    Set foundCell = Cells.Find(What:="PL " & i, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
        :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
        False, SearchFormat:=False)
    If Not foundCell Is Nothing Then
        foundCell.Copy Destination:=foundCell.Parent.Range("P" & (i + 10))
        ' BEGIN ADDITION
        If foundCell.Column > 4 Then
            foundCell.Offset(0, -4).Copy Destination:=foundCell.Parent.Range("S" & (i + 10))
        End If
        'END ADDITION
    End If
Next i

基本上，问题在于您的代码中的select。您可能想阅读以下有关如何在将来避免它们的帖子： How to avoid using Select in Excel VBA macros

Answer 2

我认为这将满足您的需求。在 J11:J100 范围内找到所需的单元格后，它会查看与找到的单元格对应的 F 列中的单元格，并将它们都粘贴到所需的单元格中。

Sub PasteTest()
Dim i As Integer
Dim SearchRange, foundCell As Range

    Set SearchRange = Range("J11:J100")
    With SearchRange
        For i = 1 To 24
            Set foundCell = .Cells.Find("PL " & i)
            If Not (foundCell Is Nothing) Then
                Range("P" & (i + 10)) = foundCell
                Set foundCell = foundCell.Offset(, -4)
                Range("S" & (i + 10)) = foundCell
            End If
        Next
End With

End Sub

与其他答案一样，我避免使用 select，因为它只会减慢代码速度。使用多个（命名的）范围允许您在不使用剪贴板的情况下复制数据。