dbms_output.put_line 即使在“设置 serveroutput on”之后也不会在过程中打印

Question

下面的程序执行得很好，但是里面的“dbms”没有打印任何输出。（程序的意思是记下工资尚未输入表中的雇员的名字） 该表有两列，即 1)name_of_emp 2)salary (默认 0)

create or replace procedure add_sal_info
as
    cursor c is select * from emp_earnings;
    cname varchar2(30);
    csal number(5);

begin
    open c;

    while(c%found) loop
        fetch c into cname, csal;
        if (csal = 0) then
            dbms_output.put_line('enter salary for : ' ||' '|| cname);
        end if;
    end loop;

    close c;
end;
/

服务器输出设置为“开”，我在执行时收到消息“程序已成功完成”，但它不打印未输入工资的员工的姓名（表中有一些）。 这里有什么症结吗？

Answer 1

c%found 在您获取一行之前不是真的，因此您永远不会进入循环。这是代码结构问题而不是dbms_output 问题。

顺便说一句，这可以简化为：

create or replace procedure add_sal_info
as
    cursor c is select * from emp_earnings;
begin
    for r in c loop
        if r.csal = 0 then
            dbms_output.put_line('enter salary for : ' ||' '|| r.cname);
        end if;
    end loop;
end;

甚至

create or replace procedure add_sal_info
as
begin
    for r in (
        select * from emp_earnings
    )
    loop
        if r.csal = 0 then
            dbms_output.put_line('enter salary for : ' ||' '|| r.cname);
        end if;
    end loop;
end;

PL/SQL 在if 或while 条件周围没有括号（它有then 关键字）。您可以将它们放在那里，但它们会被忽略。