在 ColdFusion 中加入两个数组

Question

ColdFusion 中是否有内置方法可以连接两个数组，类似于 JavaScript 的array.concat()？

Answer 1

不是真的，但你猜怎么着，只使用 Java！ :)

<cfset foo = [1,2,3]>
<cfset bar = [4,5,6]>
<cfset foo.addAll( bar )>

参考：Java's Collection Interface API.

来源：http://www.aliaspooryorik.com/blog/index.cfm/e/posts.details/post/merging-two-arrays-267

Answer 2

CF10+，使用

arrayAppend(array1, array2, true);

https://helpx.adobe.com/coldfusion/cfml-reference/coldfusion-functions/functions-a-b/arrayappend.html

Answer 3

如果您使用的是Railo，则可以使用ArrayMerge（例如<cfset NewArray=ArrayMerge(FirstArray,SecondArray)>）。

Answer 4

coldfusion 错过了脚本语言所期望的许多基本功能，这有点愚蠢。这是我必须快速写下的。

<cffunction name="mergeArrays" returntype="array" >
    <cfargument name="array1" type="array" required="true" >
    <cfargument name="array2" type="array" required="true" >

    <cfset arrayResult = arrayNew(1) >
    <cfloop array="#array1#" index="elem">
        <cfset arrayAppend(arrayResult,elem) >
    </cfloop>

    <cfloop array="#array2#" index="elem">
        <cfset arrayAppend(arrayResult,elem) >
    </cfloop>

    <cfreturn arrayResult>
</cffunction>

Answer 5

在 CF 10 或 Railo 4 中，您可以使用Underscore.cfc library 的 concat() 函数来获取一个由其他两个数组串联而成的新数组（无需修改现有数组）。示例cfscript：

newArray = _.concat([1], [2]);

结果：

// newArray == [1, 2]

使用此方法获取新数组比创建新数组并在其上调用 ArrayAppend 两次要干净一些。

（免责声明：我写了 Underscore.cfc）

Answer 6

在 javascript 中，array.join(s) 从由分隔符 s 分隔的数组的所有元素中创建一个字符串。 ColdFusion 中与此类似的函数是 ArrayToList 函数。至于将一个数组附加到另​​一个我不相信有一个 CF 函数。检查http://livedocs.adobe.com/coldfusion/8/htmldocs/help.html?content=functions-pt0_03.html#3473387 以查看 CF 中的数组函数列表。或者试试这样的：

for(index = 1; index LTE ArrayLen(array2); i = i + 1) { ArrayAppend(array1, array2[i]); }

Answer 7

您可以像这样轻松地连接两个列表：

<cfset combolist = ListAppend(lista,listb, ",")>

所以，首先使用ArrayToList() 将您的两个数组转换为列表。将两个列表与 ListAppend() 组合，然后将答案转换回带有ListToArray() 的数组。

我不知道这效率如何，但代码很简单。我很想使用 arrayAppend() 但我在 ColdFusion 8 中。

Answer 8

我从 Ben Nadel 那里得到这个，并用它来执行加密和散列。像魅力一样工作！

<cfscript>
    // Note: BinaryDecode/CharsetDecode return java arrays. 
    // Unlike CF arrays, java arrays are immutable, 
    // so the Java addAll(..) method to merge arrays won't work here. 
    // http://stackoverflow.com/a/10760835/104223

    // function to merge immutable arrays the long way
    function mergeArrays( array1, array2 ){
        var i = 0;
        var newArray = [];
        for (i = 1; i <= arrayLen(arguments.array1); i++) {
            arrayAppend(newArray, arguments.array1[i]);
        }
        for (i = 1; i <= arrayLen(arguments.array2); i++) {
            arrayAppend(newArray, arguments.array2[i]);
        }
        return newArray;
    }


    //convert the saltArray string and CustomerID string to UTF-8 byte arrays.
    saltByteArray = charsetDecode(salt, "utf-8");
    CustomerIdByteArray = charsetDecode(CustomerId, "utf-8");

    //create a new byte array consisting of the CustomerId bytes
    //appended with the salt bytes by merging the two binary arrays 
    //via custom function, mergeArrays
    mergedBytes = mergeArrays( CustomerIdByteArray, saltByteArray );
</cfscript>

Answer 9

是的，ColdFusion(10+) 有一个内置函数来追加两个数组。

脚本版本：array1.append(array2, true);

标签版本：arrayAppend(array1, array2, true);