XSLT：获取具有指定属性的父母的所有孩子

Question

鉴于此 XML：

<?xml version="1.0" encoding="iso-8859-2" ?>
<r>
    <products start="5" stop="8">
        <p>
            <id> 50 </id>
            <name> Murphy </name>
            <price> 33 </price>
        </p>
        <p>
            <id> 10 </id>
            <name> Margarethe </name>
            <price> 11 </price>
        </p>
    </products>
    <products start="1" stop="4">
        <p>
            <id> 555 </id>
            <name> XXXX</name>
            <price> 333 </price>
        </p>
        <p>
            <id> 10 </id>
            <name> Mexico </name>
            <price> 11 </price>
        </p>
    </products>
    <products start="1" stop="4">
        <p>
            <id> 30 </id>
            <name> HKoney </name>
            <price> 11 </price>
        </p>
        <p>
            <id> 10 </id>
            <name> HMargarethe </name>
            <price> 11 </price>
        </p>
    </products>
</r>

---

使用此 XSL：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
encoding="UTF-8" indent="yes"/>

<xsl:template match="products[@start &lt; 2 and @stop &gt; 2]" >
    <xsl:call-template name="test"/>
</xsl:template>

<xsl:template name="test">
     <test><xsl:value-of select="*/name"/></test>
</xsl:template>

<xsl:template match="products"/>

</xsl:stylesheet>

---

有这个输出：

<?xml version="1.0" encoding="UTF-8"?>
<test> XXXX</test>
<test> HKoney </test>

---

问：为什么我没有得到所有具有指定属性的父级的<p>，只有第一个？ Mexico 和 HMargarethe 也是预期的。

---

期望的输出：

<?xml version="1.0" encoding="UTF-8"?>
<test> XXXX</test>
<test> Mexico </test>
<test> HKoney </test>
<test> HMargerethe</test>

---

注意：我希望它在没有 for-each 循环的情况下工作。

Answer 1

您可以尝试在<name> 元素上直接使用apply-templates：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="products[@start &lt; 2 and @stop &gt; 2]" >
        <xsl:apply-templates select="p/name"/>
    </xsl:template>

    <xsl:template match="name">
        <test>
            <xsl:value-of select="."/>
        </test>
    </xsl:template>

    <xsl:template match="products"/>

</xsl:stylesheet>

Answer 2

您必须处理所有p 元素，请参阅此处的xsl:for-each：

<xsl:template name="test">
    <test>
        <xsl:for-each select="*">
            <xsl:value-of select="name"/>
        </xsl:for-each>
    </test>
</xsl:template>

Answer 3

问：为什么我没有得到所有具有指定属性的父级的<p>，只有第一个？ Mexico 和 HMargarethe 也是预期的。

注意模板test 只为每个products 元素调用一次：

<xsl:template match="products[@start &lt; 2 and @stop &gt; 2]" >
    <xsl:call-template name="test"/>
</xsl:template>

每次调用模板时，您都会拉取多个name 元素以供<xsl:value-of> 处理。根据 MSDN 关于<xsl:value-of> 的select 属性：

必填。要针对当前上下文评估的表达式 (XML)。结果被转换为字符串，就像调用 string() 函数一样。 通过在集合中插入第一个节点的字符串值，将节点集转换为字符串。

规范也讲述了同样的故事，请参阅 W3C xslt value-of 和 xpath function string()

Answer 4

修改了代码不使用for循环

请使用下面的代码，它按预期工作

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/" name ="ParentCopy">
<xsl:param name="LoopCountA">1</xsl:param>
<xsl:variable name = "Count" >
        <xsl:value-of select = "count(r/products)"/>
    </xsl:variable>
    <xsl:choose>
    <xsl:when test ="($LoopCountA  &lt;= $Count) ">
<xsl:choose>
            <xsl:when test ="r/products[$LoopCountA][@start &lt; 2 and @stop &gt; 2]">
                <test>
    <xsl:value-of select = "r/products[$LoopCountA]/p[1]/name"/>
                </test> 
<test>
                    <xsl:value-of select = "r/products[$LoopCountA]/p[2]/name"/>
</test>
            </xsl:when>
</xsl:choose>
    <xsl:call-template name="ParentCopy">
            <xsl:with-param name="LoopCountA">
<xsl:value-of select="$LoopCountA + 1"/>
            </xsl:with-param>
</xsl:call-template>
</xsl:when>
</xsl:choose>
</xsl:template>

</xsl:stylesheet>

如有任何其他疑问，请告诉我